home *** CD-ROM | disk | FTP | other *** search
/ Software Vault: The Gold Collection / Software Vault - The Gold Collection (American Databankers) (1993).ISO / cdr18 / mrun210.zip / MRUN210.H < prev    next >
Text File  |  1993-04-28  |  95KB  |  4,068 lines
  1. ;MailRun v2.10:  Header File
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This header file contains routines that are used in various
  9. * places throughout the MailRun source files.  It also contains
  10. * global variable definitions and macros.
  11. * 
  12. * #ifdef commands have been used to exclude procedures and global
  13. * variables from being compiled in any script module where they
  14. * are not needed.  In theory, it should not be necessary to do
  15. * this:  Datastorm's documentation says that any procedure or
  16. * variable that isn't used is ignored.  In practice, however, the
  17. * compiler will use up its limited memory resources allocating
  18. * space to variables and procedures that never make their way into
  19. * the compiled script.
  20. * 
  21. * The following procedures/functions are found in this file
  22. * (roughly in order of appearance):
  23. * 
  24. * makefullname(), makemrn(), makebbslist(), maketasklist(), 
  25. * makemailrunlist(), makedesc(), gettaskstring(), loadsettings(), 
  26. * loadbbsinfo(), loadprompts(), loadmaildoor(), writesettings(), 
  27. * writebbsinfo(), writeprompts(), writemaildoor(), openfile(), 
  28. * readbbs(), readitem(), writebbs(), writeitem(), getbbscoord(), 
  29. * getitemcoord(), getbbsi(), getitemi(), getfirstitem(), copymrn(), 
  30. * fverify(), cleardir(), clearfiledesc(), insertitem(), insertbbs(), 
  31. * changemailrun(), checkpending(), checkperm(), checkchild(), 
  32. * checkrunning(), checkchanged(), checkfile(), checktask(), checknew(), 
  33. * menudim(), sortidx(), fieldcompare(), findstring(), interfaceon(), 
  34. * interfaceoff(), parsedialog(), swapbbs(), swapitem(), changestatus(),
  35. * taskfilefwd(), taskfileend(), parsemenu(), parseobject(), 
  36. * filenewmrun(), filesave(), filesaveas(), filereset(), filedelmrun(), 
  37. * fileautorun(), fileexit(), editcut(), editcopy(), editpaste(), 
  38. * editdelete(), cfgmrun(), cfgbbs(), cfgprompts(), cfgmaildoor(), 
  39. * configbbs(), configmrun(), configprompts(), configmaildoor(), 
  40. * defaultsmailrun(), defaultsbbs(), defaultsprompts(), defaultsdoor(), 
  41. * addnewbbs(), addgetsend(), addupload(), adddownload(), addsendcmd(), 
  42. * addscript(), executemailrun(), executeqwkreader(), executearchiver(),
  43. * executelogviewer(), helpcontents(), helpcontext(), helpabout(),
  44. * callscript()
  45. * 
  46. **************************************************************************
  47. **************************************************************************
  48. #endcomment
  49.  
  50. ;Open file indexes
  51.  
  52. #define IniFile 0
  53. #define MailRunFile 1
  54. #define BBSFile 0
  55. #define TaskFile 1
  56. #define OldTaskFile 2
  57. #define BBSidxFile 0
  58. #define BBSdbfFile 1
  59. #define NewFilesFile 2
  60. #define MRUnarcFile 3
  61. #define OldidxFile 4
  62. #define OlddbfFile 5
  63. #define ScriptFile 0
  64. #define QueueListFile 5
  65. #define OldUBFFile 0
  66. #define OldUDXFile 1
  67. #define MRunUBFFile 2
  68. #define MRunUDXFile 3
  69. #define FileDescFile 4
  70. #define SourceFile 5
  71.  
  72. ;Flags
  73.  
  74. #define ALLFLAGS 255                ; 2^8 - 1
  75. #define RUNNING 1                    ; 2^0
  76. #define CHANGED 2                    ; 2^1
  77. #define NEW 4                        ; 2^2
  78. #define AGM 8                        ; 2^3
  79. #define CMD 16                        ; 2^4
  80. #define SCR 32                        ; 2^5
  81. #define ABT 64                        ; 2^6
  82. #define USR 8                        ; 2^3
  83. #define PRMPT 16                    ; 2^4
  84. #define QMD 32                        ; 2^5
  85. #define DEFAULTS 128                ; 2^7
  86. #define IDLE (ALLFLAGS - RUNNING)
  87. #define UNCHANGED (ALLFLAGS - CHANGED)
  88. #define OLD (ALLFLAGS - NEW)
  89. #define CLEARCMD (ALLFLAGS - AGM - CMD - SCR - ABT)
  90.  
  91. ;System global variables
  92.  
  93. #define FLAGS i9
  94. #define IdleTimeout i8
  95. #define LogRun i7
  96. #define AppendLog i6
  97. #define AnsiInLog i5
  98. #define NewfileFilter i4
  99. #define GraphicsOn i3
  100. #define HelpPage i2
  101. #define PostRun i1
  102. #define IdleTimer i0
  103.  
  104. #define TaskItem s9
  105. #define MailRun s8
  106. #define MailRunIni s7
  107. #define TempDir s6
  108. #define MailRunDir s5
  109. #define TaskList s4
  110. #define BBS s3
  111. #define Item s2
  112. #define Conf s1
  113. #define CurrentConf s0
  114.  
  115. ;Macros
  116.  
  117. #define EscapeFail 0
  118. #define ErrorFail 1
  119. #define ALPHA 0
  120. #define NUMERIC 1
  121. #define MMDDYY 2
  122. #define _READWRITE 0
  123. #define _CREATE 1
  124. #define _TEXT 0
  125. #define _NORMAL 1
  126.  
  127. ;Miscellaneous global variables
  128.  
  129. string     MailRunTrunc
  130.  
  131. #ifndef MRUN210G
  132. #ifndef MRUN210B
  133. string    BBSList
  134. #endif
  135. #ifndef MRUN210F
  136. string    BBSType
  137. #endif
  138. #ifndef MRUN210AB
  139. #ifndef MRUN210C
  140. integer PermRadio
  141. #endif
  142. #endif
  143. #endif
  144.  
  145. #ifdef MRUN210AB
  146. string MailRunList
  147. #endif
  148.  
  149. #ifdef MRUN210DE
  150. string     FileName,        FileDesc,        FileChoice
  151. #endif
  152.  
  153. ;Global variables containing values displayed in the main dialogbox
  154.  
  155. #ifdef MRUN210AG
  156. string     BBSTotal,         BBSComplete,     BBSRemaining,    AttemptNum
  157. string     ItemTotal,         ItemComplete,    ItemError,         ItemRemaining
  158. #endif
  159.  
  160.  
  161. ;Global variables containing values from [MailRun] section of *.MRN
  162.  
  163. #ifdef MRUN210AB
  164. string     MailDir,            ReplyDir,        DownloadDir,    UploadDir
  165. string    DialAttempts,    DialTimeout,    DialPause
  166. string    SavePackets,    IdleTime,        ExecTime
  167. string    Archiver,        QWKReader,        LogViewer
  168. integer  GoWait
  169. #endif
  170.  
  171.  
  172. #ifndef MRUN210DE
  173. #ifndef MRUN210F
  174. #ifndef MRUN210G
  175.  
  176. ;Global variables containing general BBS info from *.MRN
  177.  
  178. string    BBSName,            UserName,        PWord,        XferProt
  179. string    CallingFrom,    UserResp1,        UserResp2
  180. string     Number_1,        Number_2,        Number_3
  181. string    LangNumber,        MailDoorType
  182.  
  183. ;Global variables containing BBS prompts from MAILRUN.INI
  184.  
  185. string     LangPrompt,        GraphicsPrompt,    NamePrompt,            UserPrompt1
  186. string    PWordPrompt,    ViewPrompt,            FilePrompt,            UserPrompt2
  187. string    ScanPrompt,        MorePrompt,            ContinuePrompt,    CommandPrompt
  188. string    DLPrompt,        DLUnavPrompt,        ULPrompt,            ULDescPrompt
  189.  
  190. ;Global variables containing Mail Door prompts from MAILRUN.INI
  191.  
  192. string    MailPrompt,        ReceiveQWKPrompt,    MailDLPrompt,  MsgMenuPrompt
  193. string     MailXferProt,    MailULPrompt,         QWKArchiver,    MailDoor
  194.  
  195. #endif
  196. #endif
  197. #endif
  198.  
  199.  
  200. #comment
  201. *********************************************************************
  202. * 
  203. * MAKEFULLNAME()
  204. * 
  205. * Called by all modules, various procedures
  206. * 
  207. * Appends a filename to a directory name.
  208. * 
  209. *********************************************************************
  210. #endcomment
  211.  
  212. func makefullname : string
  213. strparm Directory, FileNamen
  214. string FullName
  215.     FullName = Directory
  216.     addfilename FullName FileNamen
  217.     return FullName
  218. endfunc
  219.  
  220.  
  221. #comment
  222. *********************************************************************
  223. * 
  224. * MAKEMRN()
  225. * 
  226. * Calls loadsettings(), loadbbsinfo(), loadprompts(), loadmaildoor(),
  227. * writesettings(), writebbsinfo(), writeprompts(), writemaildoor(),
  228. * makefullname(), filesave()
  229. * 
  230. * Called by:
  231. *     MRUN210A:  initialize()
  232. *     MRUN210B:  newmailrun()
  233. * 
  234. * Create the file MAILRUN.MRN and initialize it.
  235. * 
  236. *********************************************************************
  237. #endcomment
  238.  
  239. #ifdef MRUN210AB
  240. proc makemrn
  241. string DLPurgeLimit
  242. #ifndef MRUN210A
  243. string RingInterrupt
  244. #endif
  245.     ;load the defaults 
  246.     MailRun = MailRunIni
  247.     BBS = "DEFAULT"
  248.     loadsettings()
  249.     loadbbsinfo()
  250.     loadprompts()
  251.     loadmaildoor()
  252.     profilerd MailRun "MailRun" "DLPurgeLimit" DLPurgeLimit
  253.     profilerd MailRun "MailRun" "ExecTime" ExecTime
  254.     profilerd MailRun "MailRun" "GoWait" GoWait
  255.     profilerd MailRun "MailRun" "PostRun" PostRun
  256.     profilerd MailRun "MailRun" "RingInterrupt" RingInterrupt
  257.     ;write the defaults to the new mailrun
  258.     MailRun = makefullname(TempDir, MailRunTrunc)
  259.     writesettings()
  260.     writebbsinfo()
  261.     writeprompts()
  262.     writemaildoor()
  263.     profilewr MailRun "MailRun" "DLPurgeLimit" DLPurgeLimit
  264.     profilewr MailRun "MailRun" "ExecTime" ExecTime
  265.     profilewr MailRun "MailRun" "GoWait" GoWait
  266.     profilewr MailRun "MailRun" "PostRun" PostRun
  267.     profilewr MailRun "MailRun" "RingInterrupt" RingInterrupt
  268.     ;write the new mailrun to disk
  269.     filesave()
  270. endproc
  271. #endif
  272.  
  273.  
  274. #comment
  275. *********************************************************************
  276. * 
  277. * MAKEBBSLIST()
  278. * 
  279. * Calls readbbs()
  280. * 
  281. * Called by:
  282. *     MRUN210H:  editdelete(), editpaste(), callscript()
  283. *     MRUN210C:  changeuserinfo(), changeprompts(), changemaildoor()
  284. *     MRUN210D:  main()
  285. *     MRUN210E:  main()
  286. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  287. * 
  288. * Creates a list of BBSs for display the BBS combobox of
  289. * various dialog boxes.
  290. * 
  291. *********************************************************************
  292. #endcomment
  293.  
  294. #ifndef MRUN210G
  295. #ifndef MRUN210B
  296. proc makebbslist
  297. string BBSi
  298. integer i
  299.     BBSList = ""
  300.     i = 1
  301.     BBSi = readbbs(i)
  302.     while not NULLSTR BBSi
  303.         strlwr BBSi
  304.         strfmt BBSList "%s,%s" BBSList BBSi
  305.         i++
  306.         BBSi = readbbs(i)
  307.     endwhile
  308.     if i > 1
  309.         strdelete BBSList 0 1
  310.     endif
  311. endproc
  312. #endif
  313. #endif
  314.  
  315.  
  316. #comment
  317. *********************************************************************
  318. * 
  319. * MAKETASKLIST()
  320. * 
  321. * Calls openfile(), gettaskstring(), readbbs(), readitem(),
  322. * makefullname()
  323. * 
  324. * Called by:
  325. *     MRUN210H:  editdelete(), changestatus(), filereset(),
  326. *                   filedelmrun(), editpaste(), callscript()
  327. *     MRUN210A:  main(), parsedialog(), swapbbs(), executor()
  328. *     MRUN210G:  main(), dobbs()
  329. * 
  330. * 
  331. * Creates the Task List displayed in the main MailRun
  332. * dialog box.  Each item of each BBS is read from the *.MRN
  333. * file and a "TaskString" is produced to describe its contents.
  334. * The BBS and Item coordinates are appended to the TaskString
  335. * as an index back into the *.MRN file.  Tabstops are used to
  336. * push these indexes beyond the right edge of the Task List
  337. * flistbox so that they are not visible.  TaskStrings for BBS
  338. * names have an item coordinate of zero.
  339. * 
  340. * Also calculates the values of variables displayed in the
  341. * statistics section of the main dialog box.
  342. * 
  343. *********************************************************************
  344. #endcomment
  345.  
  346. #ifdef MRUN210AG
  347. proc maketasklist
  348. string TaskString, Tasks, Pending
  349. string LastBBS, LastItem, BBSNamen
  350. integer BBST, BBSC, BBSR, ItemT, ItemC, ItemE, ItemR
  351. integer i, j
  352.     ;set all values displayed in main dialog box to 0
  353.     BBST = 0
  354.     BBSC = 0
  355.     BBSR = 0
  356.     ItemT = 0
  357.     ItemC = 0
  358.     ItemE = 0
  359.     Tasks = makefullname(TempDir, "TASKLIST.TMP")
  360.     ;Save the values for the current BBS and Item
  361.     LastItem = Item
  362.     LastBBS = BBS
  363.     openfile(TaskFile, Tasks, _CREATE, _NORMAL)
  364.     i = 1
  365.     BBS = readbbs(i)
  366.     while not NULLSTR BBS
  367.         ;Loop through each BBS in the MailRun
  368.         ItemR = 0
  369.         j = 0
  370.         profilerd MailRun BBS "BBSName" BBSNamen
  371.         fstrfmt TaskFile "%s`t`t`t%d`t%d`r`n" BBSNamen i j
  372.         j++
  373.         Item = readitem(j)
  374.         while not NULLSTR Item
  375.             ;Loop through each Item
  376.             strextract Pending Item "," 0
  377.             if strcmpi Pending "0"
  378.                 ItemC++
  379.             elseif strcmpi Pending "1"
  380.                 ItemR++
  381.             else
  382.                 ItemE++
  383.             endif
  384.             TaskString = gettaskstring(i, j)
  385.             fstrfmt TaskFile "%s`r`n" TaskString
  386.             ItemT++
  387.             j++
  388.             Item = readitem(j)
  389.         endwhile
  390.         BBST++
  391.         if ItemR == 0
  392.             BBSC++
  393.         endif
  394.         i++
  395.         BBS = readbbs(i)
  396.     endwhile
  397.     fclose TaskFile
  398.     Item = LastItem
  399.     BBS = LastBBS
  400.     ;prepare statistics variables for display in the main box
  401.     BBSR = BBST - BBSC
  402.     ItemR = ItemT - ItemC - ItemE
  403.     itoa BBST BBSTotal
  404.     itoa BBSC BBSComplete
  405.     itoa BBSR BBSRemaining
  406.     itoa ItemT ItemTotal
  407.     itoa ItemC ItemComplete
  408.     itoa ItemE ItemError
  409.     itoa ItemR ItemRemaining
  410. endproc
  411. #endif
  412.  
  413.  
  414. #comment
  415. *********************************************************************
  416. * 
  417. * MAKEMAILRUNLIST()
  418. * 
  419. * Calls makefullname()
  420. * 
  421. * Called by:
  422. *     MRUN210H:  filesaveas(), filedelmrun(), callscript()
  423. *     MRUN210A:  main()
  424. *     MRUN210B:  main(), newmailrun()
  425. * 
  426. * Creates a list of MailRuns for display in the main
  427. * MailRun and MailRun Settings dialog boxes.
  428. * 
  429. *********************************************************************
  430. #endcomment
  431.  
  432. #ifdef MRUN210AB
  433. proc makemailrunlist
  434. string FileTrunc, MRNFile
  435.     MailRunList = ""
  436.     MRNFile = makefullname(MailRunDir, "*.MRN")
  437.     findfirst MRNFile
  438.     ;Loop through all files in the directory
  439.     while FOUND
  440.         FileTrunc = $FILENAME
  441.         strlwr FileTrunc
  442.         strfmt MailRunList "%s,%s" MailRunList FileTrunc
  443.         findnext
  444.     endwhile
  445.     if not NULLSTR MailRunList
  446.         strdelete MailRunList 0 1
  447.     endif
  448. endproc
  449. #endif
  450.  
  451.  
  452. #comment
  453. *********************************************************************
  454. * 
  455. * MAKEDESC()
  456. * 
  457. * Calls openfile()
  458. * 
  459. * Called by:
  460. *     MRUN210D:  main(), deldlfile()
  461. *     MRUN210E:  getnewdesc()
  462. * 
  463. * Creates the file description for display in the upload
  464. * and download dialog boxes.
  465. * 
  466. *********************************************************************
  467. #endcomment
  468.  
  469. #ifdef MRUN210DE
  470. proc makedesc
  471. strparm DescSource
  472. string DB, DL
  473. integer char
  474. long DescBegin, DescLength, counter
  475.     strextract DB FileChoice "`t" 4
  476.     atol DB DescBegin
  477.     strextract DL FileChoice "`t" 5
  478.     atol DL DescLength
  479.     if DescLength != 0
  480.         ;if there is a description in the database, retrieve it
  481.         openfile(FileDescFile, FileDesc, _CREATE, _NORMAL)
  482.         openfile(SourceFile, DescSource, _READWRITE, _NORMAL)
  483.         fseek SourceFile DescBegin 0
  484.         for counter = 1 upto DescLength
  485.             fgetc SourceFile char
  486.             fputc FileDescFile char
  487.         endfor
  488.         fclose FileDescFile
  489.         fclose SourceFile
  490.     else
  491.         ;otherwise, just delete the previous description
  492.         openfile(FileDescFile, FileDesc, _CREATE, _NORMAL)
  493.         fclose FileDescFile
  494.     endif
  495. endproc
  496. #endif
  497.  
  498.  
  499. #comment
  500. *********************************************************************
  501. * 
  502. * GETTASKSTRING()
  503. * 
  504. * Called by:
  505. *     MRUN210H:  maketasklist(), editdelete(), changestatus(),
  506. *                  editpaste()
  507. *     MRUN210A:  parsekeystate(), swapitem()
  508. *     MRUN210C:  changeuserinfo(), changeprompts(), changemaildoor()
  509. *     MRUN210D:  main()
  510. *     MRUN210E:  main()
  511. *     MRUN210F:  addgetmail(), addsendmail(), adddoscript()
  512. *     MRUN210G:  dobbs()
  513. * 
  514. * Produces a TaskString from the current *.MRN Item.
  515. * Items are strings with the format:
  516. * 
  517. *         "Pending,Perm,TaskType,FileName,Conf"
  518. * 
  519. * Pending = 0 if item is completed, 1 if pending, 2 if an
  520. *         error occurred in previous attempt to execute it.
  521. * Perm = 1 if the item is permanent; Perm = 2 if temporary.
  522. * TaskType may be SendMail, GetMail, SendFile, GetFile,
  523. *         SendCommand or SendScript.
  524. * FileName is the name of the file to be transferred, used
  525. *         by SendFile and GetFile items.
  526. * Conf is the number of the conference to be joined, used
  527. *         by SendFile and GetFile items.
  528. * 
  529. *********************************************************************
  530. #endcomment
  531.  
  532. func gettaskstring : string
  533. intparm i, j
  534. string Pending, Perm, TaskType, TaskString, KeyString, BBSNamen
  535. string char, BBS_X, Item_X, BBSi, Itemi
  536.     strfmt BBS_X "BBS_%d" i
  537.     profilerd MailRun "MailRun" BBS_X BBSi
  538.     if j == 0
  539.         ;if this is for a BBS name
  540.         profilerd MailRun BBSi "BBSName" BBSNamen
  541.         strfmt TaskString "%s`t`t`t%d`t%d" BBSNamen i j
  542.     else
  543.         ;if this is for an item
  544.         strfmt Item_X "Item_%d" j
  545.         profilerd MailRun BBSi Item_X Itemi
  546.         strextract Pending Itemi "," 0
  547.         strextract Perm Itemi "," 1
  548.         strextract TaskType Itemi "," 2
  549.         if strcmpi Pending "1"
  550.             If strcmpi Perm "1"
  551.                 char = "#"
  552.             else
  553.                 char = "ñ"
  554.             endif
  555.         elseif strcmpi Pending "0"
  556.             char = "@"
  557.         else
  558.             char = " !"
  559.         endif
  560.         switch TaskType
  561.             case "SendMail"
  562.                 TaskString = "Send REP Packet"
  563.             endcase
  564.             case "GetMail"
  565.                 TaskString = "Get QWK Packet"
  566.             endcase
  567.             case "SendFile"
  568.                 strextract KeyString Itemi "," 3
  569.                 strextract Conf Itemi "," 4
  570.                 strfmt TaskString "Upload %s to Conference %s" KeyString Conf
  571.             endcase
  572.             case "GetFile"
  573.                 strextract keystring Itemi "," 3
  574.                 strextract Conf Itemi "," 4
  575.                 strfmt TaskString "Download %s from Conference %s" KeyString Conf
  576.             endcase
  577.             case "SendCommand"
  578.                 strextract KeyString Itemi "," 3
  579.                 strfmt TaskString "Send Command:  %s" KeyString
  580.             endcase
  581.             case "SendScript"
  582.                 strextract KeyString Itemi "," 3
  583.                 strfmt TaskString "Execute Script:  %s" KeyString
  584.             endcase
  585.         endswitch
  586.         strfmt TaskString "`t%s`t%s`t%d`t%d" char TaskString i j
  587.     endif
  588.     return TaskString
  589. endfunc
  590.  
  591.  
  592. #comment
  593. *********************************************************************
  594. * 
  595. * LOADSETTINGS()
  596. * 
  597. * Called by:
  598. *     MRUN210H:  makemrn(), changemailrun()
  599. *     MRUN210B:  main()
  600. * 
  601. * Initializes MailRun settings.
  602. * 
  603. *********************************************************************
  604. #endcomment
  605.  
  606. #ifdef MRUN210AB
  607. proc loadsettings
  608. string _MailRun
  609.     if FLAGS & DEFAULTS
  610.         _MailRun = MailRunIni
  611.     else
  612.         _MailRun = MailRun
  613.     endif
  614.     profilerd _MailRun "MailRun" "MailDir" MailDir
  615.     profilerd _MailRun "MailRun" "ReplyDir" ReplyDir
  616.     profilerd _MailRun "MailRun" "DownloadDir" DownloadDir
  617.     profilerd _MailRun "MailRun" "UploadDir" UploadDir
  618.     profilerd _MailRun "MailRun" "SavePackets" SavePackets
  619.     profilerd _MailRun "MailRun" "DialAttempts" DialAttempts
  620.     profilerd _MailRun "MailRun" "DialTimeout" DialTimeout
  621.     profilerd _MailRun "MailRun" "DialPause" DialPause
  622.     profilerd _MailRun "MailRun" "IdleTimeout" IdleTimeout
  623.     profilerd _MailRun "MailRun" "LogRun" LogRun
  624.     profilerd _MailRun "MailRun" "AppendLog" AppendLog
  625.     profilerd _MailRun "MailRun" "AnsiInLog" AnsiInLog
  626.     profilerd _MailRun "MailRun" "NewfileFilter" NewfileFilter
  627.     profilerd _MailRun "MailRun" "Archiver" Archiver
  628.     profilerd _MailRun "MailRun" "QWKReader" QWKReader
  629.     profilerd _MailRun "MailRun" "LogViewer" LogViewer
  630.     itoa IdleTimeout IdleTime
  631. endproc
  632. #endif
  633.  
  634.  
  635. #comment
  636. *********************************************************************
  637. * 
  638. * WRITESETTINGS()
  639. * 
  640. * Called by:  
  641. *     MRUN210H:  makemrn()
  642. *     MRUN210B:  main()
  643. * 
  644. * Writes MailRun settings to the *.MRN file.
  645. * 
  646. *********************************************************************
  647. #endcomment
  648.  
  649. #ifdef MRUN210AB
  650. proc writesettings
  651. string _MailRun
  652.     if FLAGS & DEFAULTS
  653.         _MailRun = MailRunIni
  654.     else
  655.         _MailRun = MailRun
  656.     endif
  657.     atoi IdleTime IdleTimeout
  658.     profilewr _MailRun "MailRun" "MailDir" MailDir
  659.     profilewr _MailRun "MailRun" "ReplyDir" ReplyDir
  660.     profilewr _MailRun "MailRun" "DownloadDir" DownloadDir
  661.     profilewr _MailRun "MailRun" "UploadDir" UploadDir
  662.     profilewr _MailRun "MailRun" "DialAttempts" DialAttempts
  663.     profilewr _MailRun "MailRun" "DialTimeout" DialTimeout
  664.     profilewr _MailRun "MailRun" "DialPause" DialPause
  665.     profilewr _MailRun "MailRun" "IdleTimeout" IdleTimeout
  666.     profilewr _MailRun "MailRun" "SavePackets" SavePackets
  667.     profilewr _MailRun "MailRun" "LogRun" LogRun
  668.     profilewr _MailRun "MailRun" "AppendLog" AppendLog
  669.     profilewr _MailRun "MailRun" "AnsiInLog" AnsiInLog
  670.     profilewr _MailRun "MailRun" "NewfileFilter" NewfileFilter
  671.     profilewr _MailRun "MailRun" "Archiver" Archiver
  672.     profilewr _MailRun "MailRun" "QWKReader" QWKReader
  673.     profilewr _MailRun "MailRun" "LogViewer" LogViewer
  674. endproc
  675. #endif
  676.  
  677.  
  678. #comment
  679. *********************************************************************
  680. * 
  681. * LOADBBSINFO()
  682. * 
  683. * Called by:
  684. *     MRUN210H:  makemrn(), editcopy(), editpaste()
  685. *     MRUN210C:  changeuserinfo(), addbbs()
  686. * 
  687. * Initializes BBS information.
  688. * 
  689. *********************************************************************
  690. #endcomment
  691.  
  692. #ifndef MRUN210DE
  693. #ifndef MRUN210F
  694. #ifndef MRUN210G
  695. proc loadbbsinfo
  696. string _BBS
  697.     if FLAGS & DEFAULTS
  698.         _BBS = "DEFAULT"
  699.     else
  700.         _BBS = BBS
  701.     endif
  702.     profilerd MailRun _BBS "BBSName" BBSName
  703.     profilerd MailRun _BBS "UserName" UserName
  704.     profilerd MailRun _BBS "PWord" Pword
  705.     profilerd MailRun _BBS "XferProt" XferProt
  706.     profilerd MailRun _BBS "MailXferProt" MailXferProt
  707.     profilerd MailRun _BBS "QWKArchiver" QWKArchiver
  708.     profilerd MailRun _BBS "Number_1" Number_1
  709.     profilerd MailRun _BBS "Number_2" Number_2
  710.     profilerd MailRun _BBS "Number_3" Number_3
  711.     profilerd MailRun _BBS "BBSType" BBSType
  712.     profilerd MailRun _BBS "MailDoorType" MailDoorType
  713. endproc
  714. #endif
  715. #endif
  716. #endif
  717.  
  718.  
  719. #comment
  720. *********************************************************************
  721. * 
  722. * WRITEBBSINFO()
  723. * 
  724. * Called by:
  725. *     MRUN210H:  makemrn(), editcopy(), editpaste()
  726. *     MRUN210C:  changeuserinfo()
  727. * 
  728. * Writes information for current BBS to the *.MRN file.
  729. * 
  730. *********************************************************************
  731. #endcomment
  732.  
  733. #ifndef MRUN210DE
  734. #ifndef MRUN210F
  735. #ifndef MRUN210G
  736. proc writebbsinfo
  737. string _BBS
  738.     if FLAGS & DEFAULTS
  739.         _BBS = "DEFAULT"
  740.     else
  741.         _BBS = BBS
  742.     endif
  743.     profilewr MailRun _BBS "BBSName" BBSName
  744.     profilewr MailRun _BBS "UserName" UserName
  745.     profilewr MailRun _BBS "PWord" PWord
  746.     profilewr MailRun _BBS "XferProt" XferProt
  747.     profilewr MailRun _BBS "MailXferProt" MailXferProt
  748.     profilewr MailRun _BBS "QWKArchiver" QWKArchiver
  749.     profilewr MailRun _BBS "Number_1" Number_1
  750.     profilewr MailRun _BBS "Number_2" Number_2
  751.     profilewr MailRun _BBS "Number_3" Number_3
  752.     profilewr MailRun _BBS "BBSType" BBSType
  753.     profilewr MailRun _BBS "MailDoorType" MailDoorType
  754. endproc
  755. #endif
  756. #endif
  757. #endif
  758.  
  759.  
  760. #comment
  761. *********************************************************************
  762. * 
  763. * LOADPROMPTS()
  764. * 
  765. * Called by:
  766. *     MRUN210H:  makemrn(), editcopy(), editpaste()
  767. *     MRUN210C:  changeuserinfo(), changeprompts(), addbbs()
  768. * 
  769. * Initializes BBS prompts.
  770. * 
  771. *********************************************************************
  772. #endcomment
  773.  
  774. #ifndef MRUN210DE
  775. #ifndef MRUN210F
  776. #ifndef MRUN210G
  777. proc loadprompts
  778. string _MailRun, _BBS
  779.     if FLAGS & DEFAULTS
  780.         _MailRun = MailRunIni
  781.         _BBS = BBSType
  782.     else
  783.         _MailRun = MailRun
  784.         _BBS = BBS
  785.     endif
  786.     profilerd _MailRun _BBS "CallingFrom" CallingFrom
  787.     profilerd _MailRun _BBS "UserResp1" UserResp1
  788.     profilerd _MailRun _BBS "UserResp2" UserResp2
  789.     profilerd _MailRun _BBS "LangNumber" LangNumber
  790.     profilerd _MailRun _BBS "GraphicsOn" GraphicsOn
  791.     profilerd _MailRun _BBS "LangPrompt" LangPrompt
  792.     profilerd _MailRun _BBS "GraphicsPrompt" GraphicsPrompt
  793.     profilerd _MailRun _BBS "NamePrompt" NamePrompt
  794.     profilerd _MailRun _BBS "PWordPrompt" PWordPrompt
  795.     profilerd _MailRun _BBS "UserPrompt1" UserPrompt1
  796.     profilerd _MailRun _BBS "UserPrompt2" UserPrompt2
  797.     profilerd _MailRun _BBS "ViewPrompt" ViewPrompt
  798.     profilerd _MailRun _BBS "ScanPrompt" ScanPrompt
  799.     profilerd _MailRun _BBS "FilePrompt" FilePrompt
  800.     profilerd _MailRun _BBS "MorePrompt" MorePrompt
  801.     profilerd _MailRun _BBS "ContinuePrompt" ContinuePrompt
  802.     profilerd _MailRun _BBS "CommandPrompt" CommandPrompt
  803.     profilerd _MailRun _BBS "DLPrompt" DLPrompt
  804.     profilerd _MailRun _BBS "DLUnavPrompt" DLUnavPrompt
  805.     profilerd _MailRun _BBS "ULPrompt" ULPrompt
  806.     profilerd _MailRun _BBS "ULDescPrompt" ULDescPrompt
  807. endproc
  808. #endif
  809. #endif
  810. #endif
  811.  
  812.  
  813. #comment
  814. *********************************************************************
  815. * 
  816. * WRITEPROMPTS()
  817. * 
  818. * Called by:
  819. *     MRUN210H:  makemrn(), editcopy(), editpaste()
  820. *     MRUN210C:  changeuserinfo(), changeprompts(), exportprompts()
  821. * 
  822. * Writes prompts for current BBS to the *.MRN file.
  823. * 
  824. *********************************************************************
  825. #endcomment
  826.  
  827. #ifndef MRUN210DE
  828. #ifndef MRUN210F
  829. #ifndef MRUN210G
  830. proc writeprompts
  831. string _MailRun, _BBS
  832.     if FLAGS & DEFAULTS
  833.         _MailRun = MailRunIni
  834.         _BBS = BBSType
  835.     else
  836.         _MailRun = MailRun
  837.         _BBS = BBS
  838.     endif
  839.     profilewr _MailRun _BBS "CallingFrom" CallingFrom
  840.     profilewr _MailRun _BBS "UserResp1" UserResp1
  841.     profilewr _MailRun _BBS "UserResp2" UserResp2
  842.     profilewr _MailRun _BBS "LangNumber" LangNumber
  843.     profilewr _MailRun _BBS "GraphicsOn" GraphicsOn
  844.     profilewr _MailRun _BBS "LangPrompt" LangPrompt
  845.     profilewr _MailRun _BBS "GraphicsPrompt" GraphicsPrompt
  846.     profilewr _MailRun _BBS "NamePrompt" NamePrompt
  847.     profilewr _MailRun _BBS "PWordPrompt" PWordPrompt
  848.     profilewr _MailRun _BBS "UserPrompt1" UserPrompt1
  849.     profilewr _MailRun _BBS "UserPrompt2" UserPrompt2
  850.     profilewr _MailRun _BBS "ViewPrompt" ViewPrompt
  851.     profilewr _MailRun _BBS "ScanPrompt" ScanPrompt
  852.     profilewr _MailRun _BBS "FilePrompt" FilePrompt
  853.     profilewr _MailRun _BBS "MorePrompt" MorePrompt
  854.     profilewr _MailRun _BBS "ContinuePrompt" ContinuePrompt
  855.     profilewr _MailRun _BBS "CommandPrompt" CommandPrompt
  856.     profilewr _MailRun _BBS "DLPrompt" DLPrompt
  857.     profilewr _MailRun _BBS "DLUnavPrompt" DLUnavPrompt
  858.     profilewr _MailRun _BBS "ULPrompt" ULPrompt
  859.     profilewr _MailRun _BBS "ULDescPrompt" ULDescPrompt
  860. endproc
  861. #endif
  862. #endif
  863. #endif
  864.  
  865.  
  866. #comment
  867. *********************************************************************
  868. * 
  869. * LOADMAILDOOR()
  870. * 
  871. * Called by:
  872. *     MRUN210H:  makemrn(), editcopy(), editpaste()
  873. *     MRUN210C:  changeuserinfo(), changemaildoor(), addbbs()
  874. * 
  875. * Initializes mail door prompts.
  876. * 
  877. *********************************************************************
  878. #endcomment
  879.  
  880. #ifndef MRUN210DE
  881. #ifndef MRUN210F
  882. #ifndef MRUN210G
  883. proc loadmaildoor
  884. string _MailRun, _BBS
  885.     if FLAGS & DEFAULTS
  886.         _MailRun = MailRunIni
  887.         _BBS = MailDoorType
  888.     else
  889.         _MailRun = MailRun
  890.         _BBS = BBS
  891.     endif
  892.     profilerd _MailRun _BBS "MailDoor" MailDoor
  893.     profilerd _MailRun _BBS "MailPrompt" MailPrompt
  894.     profilerd _MailRun _BBS "ReceiveQWKPrompt" ReceiveQWKPrompt
  895.     profilerd _MailRun _BBS "MailDLPrompt" MailDLPrompt
  896.     profilerd _MailRun _BBS "MailULPrompt" MailULPrompt
  897.     profilerd _MailRun _BBS "MsgMenuPrompt" MsgMenuPrompt
  898. endproc
  899. #endif
  900. #endif
  901. #endif
  902.  
  903.  
  904. #comment
  905. *********************************************************************
  906. * 
  907. * WRITEMAILDOOR()
  908. * 
  909. * Called by:
  910. *     MRUN210H:  makemrn(), editcopy(), editpaste()
  911. *     MRUN210C:  changeuserinfo(), changemaildoor(), 
  912. *                   exportmaildoor()
  913. * 
  914. * Writes mail door prompts for the current BBS to the .MRN
  915. * file.
  916. * 
  917. *********************************************************************
  918. #endcomment
  919.  
  920. #ifndef MRUN210DE
  921. #ifndef MRUN210F
  922. #ifndef MRUN210G
  923. proc writemaildoor
  924. string _MailRun, _BBS
  925.     if FLAGS & DEFAULTS
  926.         _MailRun = MailRunIni
  927.         _BBS = MailDoorType
  928.     else
  929.         _MailRun = MailRun
  930.         _BBS = BBS
  931.     endif
  932.     profilewr _MailRun _BBS "MailDoor" MailDoor
  933.     profilewr _MailRun _BBS "MailPrompt" MailPrompt
  934.     profilewr _MailRun _BBS "ReceiveQWKPrompt" ReceiveQWKPrompt
  935.     profilewr _MailRun _BBS "MailDLPrompt" MailDLPrompt
  936.     profilewr _MailRun _BBS "MailULPrompt" MailULPrompt
  937.     profilewr _MailRun _BBS "MsgMenuPrompt" MsgMenuPrompt
  938. endproc
  939. #endif
  940. #endif
  941. #endif
  942.  
  943.  
  944. #comment
  945. *********************************************************************
  946. * 
  947. * OPENFILE()
  948. * 
  949. * Calls fileexit()
  950. * 
  951. * Called by:
  952. *     MRUN210H:  maketasklist(), makedesc(), clearfiledesc(),
  953. *                   sortidx(), taskfilefwd()
  954. *     MRUN210D:  main(), purgeoldfiles(), getnewfiles(),
  955. *                   import(), deldlfile()
  956. *     MRUN210E:  insertulfile(), killfile(), getulfiles(),
  957. *                   updateudx()
  958. *     MRUN210F:  makescriptlist()
  959. *     MRUN210G:  makequeue(), getdialstring(), senddesc(), putdesc()
  960. * 
  961. * Opens a file in the manner specified.  If the file could
  962. * not be opened successfully, displays an error message and
  963. * terminates the script.
  964. * 
  965. *********************************************************************
  966. #endcomment
  967.  
  968. proc openfile
  969. intparm FileIndex
  970. strparm FileNamen
  971. intparm OpenMethod, OpenType
  972.     switch OpenMethod
  973.         case _CREATE
  974.             switch OpenType
  975.                 case _TEXT
  976.                     fopen FileIndex FileNamen CREATE TEXT
  977.                 endcase
  978.                 case _NORMAL
  979.                     fopen FileIndex FileNamen CREATE
  980.                 endcase
  981.             endswitch
  982.         endcase
  983.         case _READWRITE
  984.             switch OpenType
  985.                 case _TEXT
  986.                     fopen FileIndex FileNamen READWRITE TEXT
  987.                 endcase
  988.                 case _NORMAL
  989.                     fopen FileIndex FileNamen READWRITE
  990.                 endcase
  991.             endswitch
  992.         endcase
  993.     endswitch
  994.     if FAILURE
  995.         errormsg "Unable to open file %s;`r`nscript aborted...." FileNamen
  996.         fileexit()
  997.     endif
  998. endproc
  999.  
  1000.  
  1001. #comment
  1002. *********************************************************************
  1003. * 
  1004. * READBBS()
  1005. * 
  1006. * Called by:
  1007. *     MRUN210H:  makebbslist(), maketasklist(), getbbscoord(),
  1008. *                   getbbsi(), insertbbs(), editdelete(),
  1009. *                   filereset()
  1010. *     MRUN210A:  swapbbs()
  1011. *     MRUN210G:  main(), makequeue()
  1012. * 
  1013. * Reads the BBS associated with a BBS coordinate in the
  1014. * current mailrun.
  1015. * 
  1016. *********************************************************************
  1017. #endcomment
  1018.  
  1019. func readbbs : string
  1020. intparm i
  1021. string BBS_X, BBSi
  1022.     strfmt BBS_X "BBS_%d" i
  1023.     profilerd MailRun "MailRun" BBS_X BBSi
  1024.     return BBSi
  1025. endfunc
  1026.  
  1027.  
  1028. #comment
  1029. *********************************************************************
  1030. * 
  1031. * READITEM()
  1032. * 
  1033. * Called by:
  1034. *     MRUN210H:  maketasklist(), getitemcoord(), getitemi(),
  1035. *                   insertitem(), editdelete(), filereset(),
  1036. *                   changestatus(), checkpending(), editcopy()
  1037. *     MRUN210A:  swapitem()
  1038. *     MRUN210G:  dobbs()
  1039. * 
  1040. * Reads the Item associated with a BBS coordinate in the
  1041. * current mailrun.
  1042. * 
  1043. *********************************************************************
  1044. #endcomment
  1045.  
  1046. func readitem : string
  1047. intparm i
  1048. string Item_X, Itemi
  1049.     strfmt Item_X "Item_%d" i
  1050.     profilerd MailRun BBS Item_X Itemi
  1051.     return Itemi
  1052. endfunc
  1053.  
  1054.  
  1055. #comment
  1056. *********************************************************************
  1057. * 
  1058. * WRITEBBS()
  1059. * 
  1060. * Called by:
  1061. *     MRUN210H:  insertbbs(), editdelete()
  1062. *     MRUN210A:  swapbbs()
  1063. *     MRUN210C:  writenewbbs()
  1064. * 
  1065. * Writes a BBS ID to the given coordinate in the current
  1066. * mailrun.
  1067. * 
  1068. *********************************************************************
  1069. #endcomment
  1070.  
  1071. proc writebbs
  1072. intparm i
  1073. strparm BBSi
  1074. string BBS_X
  1075.     strfmt BBS_X "BBS_%d" i
  1076.     profilewr MailRun "MailRun" BBS_X BBSi
  1077. endproc
  1078.  
  1079.  
  1080. #comment
  1081. *********************************************************************
  1082. * 
  1083. * WRITEITEM()
  1084. * 
  1085. * Called by:
  1086. *     MRUN210H:  insertitem(), editdelete(), filereset(),
  1087. *                   changestatus()
  1088. *     MRUN210A:  swapitem()
  1089. *     MRUN210G:  dobbs()
  1090. * 
  1091. * Writes an Item to the given Item coordinate for the
  1092. * current BBS and MailRun.
  1093. * 
  1094. *********************************************************************
  1095. #endcomment
  1096.  
  1097. proc writeitem
  1098. intparm i
  1099. strparm Itemi
  1100. string Item_X
  1101.     strfmt Item_X "Item_%d" i
  1102.     profilewr MailRun BBS Item_X Itemi
  1103. endproc
  1104.  
  1105.  
  1106. #comment
  1107. *********************************************************************
  1108. * 
  1109. * GETBBSCOORD()
  1110. * 
  1111. * Calls readbbs()
  1112. * 
  1113. * Called by:
  1114. *     MRUN210C:  changeuserinfo(), changeprompts(), changemaildoor()
  1115. *     MRUN210D:  main()
  1116. *     MRUN210E:  main()
  1117. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  1118. * 
  1119. * Gets the BBS coordinate for a given BBS ID.
  1120. * 
  1121. *********************************************************************
  1122. #endcomment
  1123.  
  1124. func getbbscoord : integer
  1125. integer i
  1126. string BBSi
  1127.     i = 1
  1128.     BBSi = readbbs(i)
  1129.     while not strcmpi BBS BBSi
  1130.         i++
  1131.         BBSi = readbbs(i)
  1132.     endwhile
  1133.     return i
  1134. endfunc
  1135.  
  1136.  
  1137. #comment
  1138. *********************************************************************
  1139. * 
  1140. * GETITEMCOORD()
  1141. * 
  1142. * Calls readitem()
  1143. * 
  1144. * Called by:
  1145. *     MRUN210D:  main()
  1146. *     MRUN210E:  main()
  1147. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  1148. * 
  1149. * Gets the Item coordinate for a given Item in the current
  1150. * BBS.
  1151. * 
  1152. *********************************************************************
  1153. #endcomment
  1154.  
  1155. func getitemcoord : integer
  1156. integer i
  1157.     i = 1
  1158.     Item = readitem(i)
  1159.     while not NULLSTR Item
  1160.         i++
  1161.         Item = readitem(i)
  1162.     endwhile
  1163.     i--
  1164.     Item = readitem(i)
  1165.     return i
  1166. endfunc
  1167.  
  1168.  
  1169. #comment
  1170. *********************************************************************
  1171. * 
  1172. * GETBBSI()
  1173. * 
  1174. * Calls readbbs()
  1175. * 
  1176. * Called by:
  1177. *     MRUN210H:  editdelete(), changestatus(), editcopy(),
  1178. *                   editpaste()
  1179. *     MRUN210A:  parsekeystate()
  1180. *     MRUN210C:  changeuserinfo(), changeprompts(), changemaildoor()
  1181. *     MRUN210D:  main()
  1182. *     MRUN210E:  main()
  1183. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  1184. * 
  1185. * Gets the BBS ID associated with the currently selected
  1186. * item in the task list.  Returns the integer value of the
  1187. * BBS coordinate.
  1188. * 
  1189. *********************************************************************
  1190. #endcomment
  1191.  
  1192. func getbbsi : integer
  1193. string char
  1194. integer i
  1195.     strextract char TaskItem "`t" 3
  1196.     atoi char i
  1197.     BBS = readbbs(i)
  1198.     return i
  1199. endfunc
  1200.  
  1201.  
  1202. #comment
  1203. *********************************************************************
  1204. * 
  1205. * GETITEMI()
  1206. * 
  1207. * Calls readitem()
  1208. * 
  1209. * Called by:
  1210. *     MRUN210H:  editdelete(), changestatus(), editcopy(),
  1211. *                   editpaste()
  1212. *     MRUN210A:  parsekeystate()
  1213. *     MRUN210D:  main()
  1214. *     MRUN210E:  main()
  1215. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  1216. * 
  1217. * Gets the Item associated with the currently selected item
  1218. * in the task list.  Returns the integer value of the Item
  1219. * coordinate.
  1220. * 
  1221. *********************************************************************
  1222. #endcomment
  1223.  
  1224. func getitemi : integer
  1225. string char
  1226. integer i
  1227.     strextract char TaskItem "`t" 4
  1228.     atoi char i
  1229.     Item = readitem(i)
  1230.     return i
  1231. endfunc
  1232.  
  1233.  
  1234. #comment
  1235. *********************************************************************
  1236. * 
  1237. * GETFIRSTITEM()
  1238. * 
  1239. * Called by:
  1240. *     MRUN210H:  filereset(), filedelmrun(), callscript()
  1241. *     MRUN210A:  main(), parsedialog()
  1242. * 
  1243. * Highlights the first item in the task list.
  1244. * 
  1245. *********************************************************************
  1246. #endcomment
  1247.  
  1248. proc getfirstitem
  1249. string BBSNamen
  1250.     profilerd MailRun "MailRun" "BBS_1" BBS
  1251.     if not NULLSTR BBS
  1252.         profilerd MailRun BBS "BBSName" BBSNamen
  1253.         strfmt TaskItem "%s`t`t`t%d`t%d" BBSNamen 1 0
  1254.     else
  1255.         TaskItem = ""
  1256.     endif
  1257. endproc
  1258.  
  1259.  
  1260. #comment
  1261. *********************************************************************
  1262. * 
  1263. * COPYMRN()
  1264. * 
  1265. * Calls makefullname()
  1266. * 
  1267. * Called by:
  1268. *     MRUN210H:  changemailrun(), filesaveas(), filedelmrun()
  1269. * 
  1270. * Copies a mailrun from MailRunDir to TempDir.
  1271. * 
  1272. *********************************************************************
  1273. #endcomment
  1274.  
  1275. #ifdef MRUN210AB
  1276. proc copymrn
  1277. string LastRun
  1278.     delfile MailRun
  1279.     LastRun = makefullname(MailRunDir, MailRunTrunc)
  1280.     MailRun = makefullname(TempDir, MailRunTrunc)
  1281.     copyfile LastRun MailRun
  1282. endproc
  1283. #endif
  1284.  
  1285.  
  1286. #comment
  1287. *********************************************************************
  1288. * 
  1289. * FVERIFY()
  1290. * 
  1291. * Called by:
  1292. *     MRUN210H:  filesaveas()
  1293. *     MRUN210B:  newmailrun()
  1294. *     MRUN210C:  addbbs()
  1295. * 
  1296. * Checks for a valid DOS filename (sans extension).
  1297. * Returns 1 if valid, 0 if invalid.
  1298. * 
  1299. *********************************************************************
  1300. #endcomment
  1301.  
  1302. #ifndef MRUN210DE
  1303. #ifndef MRUN210F
  1304. #ifndef MRUN210G
  1305. func fverify : integer
  1306. strparm LookString
  1307. string DOSChars = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ!@#$%^&()-_{}"
  1308. string char
  1309. integer i, j
  1310.     strlen LookString i
  1311.     if (i > 8) || (i == 0)
  1312.         return 0
  1313.     else
  1314.         i = 0
  1315.         strpeek LookString i j
  1316.         while j != 0
  1317.             strfmt char "%c" j
  1318.             if not strfind DOSChars char
  1319.                 return 0
  1320.             endif
  1321.             i++
  1322.             strpeek LookString i j
  1323.         endwhile
  1324.         return 1
  1325.     endif
  1326. endfunc
  1327. #endif
  1328. #endif
  1329. #endif
  1330.  
  1331.  
  1332. #comment
  1333. *********************************************************************
  1334. * 
  1335. * CLEARDIR()
  1336. * 
  1337. * Calls makefullname()
  1338. * 
  1339. * Called by:
  1340. *     MRUN210H:  fileexit()
  1341. *     MRUN210A:  initialize()
  1342. *     MRUN210G:  getmail()
  1343. * 
  1344. * Deletes the contents of a directory.
  1345. * 
  1346. *********************************************************************
  1347. #endcomment
  1348.  
  1349. proc cleardir
  1350. strparm DirName
  1351. string DeadFile, DirFiles
  1352.     DirFiles = makefullname(DirName, "*.*")
  1353.     findfirst DirFiles
  1354.     while FOUND
  1355.         DeadFile = makefullname(DirName, $FILENAME)
  1356.         delfile DeadFile
  1357.         findnext
  1358.     endwhile
  1359. endproc
  1360.  
  1361.  
  1362. #comment
  1363. *********************************************************************
  1364. * 
  1365. * CLEARFILEDESC()
  1366. * 
  1367. * Calls openfile()
  1368. * 
  1369. * Called by:
  1370. *     MRUN210D:  main(), deldlfile()
  1371. *     MRUN210E:  main(), insertulfile(), killfile()
  1372. * 
  1373. * Clears the current file description box by creating a
  1374. * new file.
  1375. * 
  1376. *********************************************************************
  1377. #endcomment
  1378.  
  1379. #ifdef MRUN210DE
  1380. proc clearfiledesc
  1381.     openfile(FileDescFile, FileDesc, _CREATE, _NORMAL)
  1382.     fclose FileDescFile
  1383. endproc
  1384. #endif
  1385.  
  1386.  
  1387. #comment
  1388. *********************************************************************
  1389. * 
  1390. * INSERTITEM()
  1391. * 
  1392. * Calls readitem(), writeitem()
  1393. * 
  1394. * Called by:
  1395. *     MRUN210H:  editpaste()
  1396. *     MRUN210D:  main()
  1397. *     MRUN210E:  insertulfile()
  1398. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  1399. * 
  1400. * Inserts a new item into the *.MRN file.
  1401. * 
  1402. *********************************************************************
  1403. #endcomment
  1404.  
  1405. proc insertitem
  1406. intparm i
  1407. strparm NovumItem
  1408. integer j, k
  1409.     j = i - 1
  1410.     Item = readitem(i)
  1411.     while not NULLSTR Item
  1412.         i++
  1413.         Item = readitem(i)
  1414.     endwhile
  1415.     k = i - 1
  1416.     while k > j
  1417.         Item = readitem(k)
  1418.         writeitem(i, Item)
  1419.         i--
  1420.         k--
  1421.     endwhile
  1422.     writeitem(i, NovumItem)
  1423.     Item = NovumItem
  1424. endproc
  1425.  
  1426.  
  1427. #comment
  1428. *********************************************************************
  1429. * 
  1430. * INSERTBBS()
  1431. * 
  1432. * Calls readbbs(), writebbs()
  1433. * 
  1434. * Called by:
  1435. *     MRUN210H:  editpaste()
  1436. *     MRUN210C:  writenewbbs()
  1437. * 
  1438. * Inserts a new BBS into the *.MRN file.
  1439. * 
  1440. *********************************************************************
  1441. #endcomment
  1442.  
  1443. #ifndef MRUN210B
  1444. #ifndef MRUN210DE
  1445. #ifndef MRUN210F
  1446. #ifndef MRUN210G
  1447. proc insertbbs
  1448. intparm i
  1449. strparm NewBBS
  1450. string BBSi
  1451. integer j, k
  1452.     j =  i + 1
  1453.     BBSi = readbbs(j)
  1454.     ;Go to the last BBS
  1455.     while not NULLSTR BBSi
  1456.         j++
  1457.         BBSi = readbbs(j)
  1458.     endwhile
  1459.     k = j - 1
  1460.     ;Count back down, renumbering on the way
  1461.     while k > i
  1462.         BBSi = readbbs(k)
  1463.         writebbs(j, BBSi)
  1464.         j--
  1465.         k--
  1466.     endwhile
  1467.     writebbs(j, NewBBS)
  1468. endproc
  1469. #endif
  1470. #endif
  1471. #endif
  1472. #endif
  1473.  
  1474.  
  1475. #comment
  1476. *********************************************************************
  1477. * 
  1478. * CHANGEMAILRUN()
  1479. * 
  1480. * Calls filesave(), copymrn(), loadsettings()
  1481. * 
  1482. * Called by: 
  1483. *     MRUN210A:  parsedialog()
  1484. *     MRUN210B:  main()
  1485. * 
  1486. * Saves the last mailrun and loads a new one.
  1487. * 
  1488. *********************************************************************
  1489. #endcomment
  1490.  
  1491. #ifdef MRUN210AB
  1492. proc changemailrun
  1493.     ;Update the last mailrun
  1494.     filesave()
  1495.     ;Get the next mailrun and copy it to the temp directory
  1496.     copymrn()
  1497.     loadsettings()
  1498. endproc
  1499. #endif
  1500.  
  1501.  
  1502. #comment
  1503. *********************************************************************
  1504. * 
  1505. * CHECKPENDING()
  1506. * 
  1507. * Calls readitem()
  1508. * 
  1509. * Called by:
  1510. *     MRUN210H:  changestatus()
  1511. *     MRUN210G:  makequeue()
  1512. * 
  1513. * Checks a BBS for currently pending items.  Returns "1" if
  1514. * items are pending, "0" if none are pending.
  1515. * 
  1516. *********************************************************************
  1517. #endcomment
  1518.  
  1519. #ifdef MRUN210AG
  1520. func checkpending : string
  1521. string Pending = "0"
  1522. integer i
  1523.     i = 1
  1524.     Item = readitem(i)
  1525.     while not NULLSTR Item
  1526.         strextract pending Item "," 0
  1527.         if strcmpi Pending "1"
  1528.             exitwhile
  1529.         endif
  1530.         i++
  1531.         Item = readitem(i)
  1532.     endwhile
  1533.     return Pending
  1534. endfunc
  1535. #endif
  1536.  
  1537.  
  1538. #comment
  1539. *********************************************************************
  1540. * 
  1541. * CHECKPERM()
  1542. * 
  1543. * Called by:
  1544. *     MRUN210D:  main()
  1545. *     MRUN210E:  insertulfile()
  1546. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  1547. * 
  1548. * Checks the Temporary/Permanent radiobutton set; returns
  1549. * 1 if Permanent (button 1) is selected, 0 if Temporary
  1550. * (button 2).
  1551. * 
  1552. *********************************************************************
  1553. #endcomment
  1554.  
  1555. #ifndef MRUN210AG
  1556. #ifndef MRUN210C
  1557. #ifndef MRUN210B
  1558. func checkperm : string
  1559. string Perm
  1560.     if PermRadio == 1
  1561.         Perm = "1"
  1562.     else
  1563.         Perm = "0"
  1564.     endif
  1565.     return Perm
  1566. endfunc
  1567. #endif
  1568. #endif
  1569. #endif
  1570.  
  1571.  
  1572. #comment
  1573. *********************************************************************
  1574. * 
  1575. * CHECKCHILD()
  1576. * 
  1577. * Called by:
  1578. *     MRUN210A-G:  main()
  1579. * 
  1580. * Halts the script if the current script has not been
  1581. * called by another script.
  1582. * 
  1583. *********************************************************************
  1584. #endcomment
  1585.  
  1586. proc checkchild
  1587.     if not ($CHILD || $CHAINED)
  1588.         errormsg "This script can only be run from MRUN210.WAX."
  1589.         halt
  1590.     endif
  1591. endproc
  1592.  
  1593.  
  1594. #comment
  1595. *********************************************************************
  1596. * 
  1597. * CHECKRUNNING()
  1598. * 
  1599. * Called by:
  1600. *     MRUN210H:  filenewmrun()
  1601. * 
  1602. * Checks whether a mailrun is executing.  Returns 0 and
  1603. * generates a message if running, returns 1 if not.
  1604. * 
  1605. *********************************************************************
  1606. #endcomment
  1607.  
  1608. #ifndef MRUN210G
  1609. func checkrunning : integer
  1610.     if FLAGS & RUNNING
  1611.         usermsg "You cannot create a new mailrun while a mailrun is executing."
  1612.         return 0
  1613.     else
  1614.         return 1
  1615.     endif
  1616. endfunc
  1617. #endif
  1618.  
  1619.  
  1620. #comment
  1621. *********************************************************************
  1622. * 
  1623. * CHECKCHANGED()
  1624. * 
  1625. * Called by:
  1626. *     MRUN210H:  filenewmrun(), cfgmrun(), cfgbbs(), cfgprompts(),
  1627. *                   cfgmaildoor(), defaultsmailrun(), defaultsbbs(),
  1628. *                   defaultsprompts(), defaultsdoor(), addnewbbs(),
  1629. *                   addgetsend(), adddownload(), addupload(), 
  1630. *                   addsendcmd(), addscript(), helpabout()
  1631. *     MRUN210B:  main()
  1632. *     MRUN210C:  changebbsinfo(), changeprompts(), changemaildoor()
  1633. *     MRUN210E:  main()
  1634. * 
  1635. * Checks whether the contents of the current dialog box
  1636. * have changed and generates a warning.  Returns 1 if
  1637. * user elects to proceed or if there has been no change,
  1638. * 0 if user cancels.
  1639. * 
  1640. *********************************************************************
  1641. #endcomment
  1642.  
  1643. func checkchanged : integer
  1644. integer Response
  1645.     if FLAGS & CHANGED
  1646.         sdlgmsgbox "MailRun Message" "Discard Changes?" QUESTION YESNO \
  1647.             Response 2
  1648.         switch Response
  1649.             case 6
  1650.                 FLAGS &= UNCHANGED
  1651.                 return 1
  1652.             endcase
  1653.             case 7
  1654.                 return 0
  1655.             endcase
  1656.         endswitch
  1657.     else
  1658.         return 1
  1659.     endif
  1660. endfunc
  1661.  
  1662.  
  1663. #comment
  1664. *********************************************************************
  1665. * 
  1666. * CHECKFILE()
  1667. * 
  1668. * Called by:
  1669. *     MRUN210A:  initialize()
  1670. *     MRUN210D:  purgeoldfiles(), getnewfiles(), import()
  1671. *     MRUN210E:  main(), getulfiles()
  1672. *     MRUN210G:  senddesc(), putdesc()
  1673. * 
  1674. * Checks for a file's existence.  Returns 1 if the file is
  1675. * found, 0 if not found.
  1676. * 
  1677. *********************************************************************
  1678. #endcomment
  1679.  
  1680. #ifndef MRUN210BC
  1681. #ifndef MRUN210F
  1682. func checkfile : integer
  1683. strparm FileNom
  1684.     if isfile FileNom
  1685.         return 1
  1686.     else
  1687.         return 0
  1688.     endif
  1689. endfunc
  1690. #endif
  1691. #endif
  1692.  
  1693.  
  1694. #comment
  1695. *********************************************************************
  1696. * 
  1697. * CHECKTASK()
  1698. * 
  1699. * Called by:
  1700. *     MRUN210H:  executearchiver(), executeqwkreader(),
  1701. *                   executelogviewer()
  1702. * 
  1703. * Returns 1 if the specified application is already running;
  1704. * otherwise returns 0.
  1705. * 
  1706. *********************************************************************
  1707. #endcomment
  1708.  
  1709. func checktask : integer
  1710. strparm Called
  1711. string AppName
  1712. integer i
  1713.     firsttask i
  1714.     while i
  1715.         taskname i AppName
  1716.         if strfind Called AppName
  1717.             return i
  1718.         endif
  1719.         nexttask i
  1720.     endwhile
  1721.     return 0
  1722. endfunc
  1723.  
  1724.  
  1725. #comment
  1726. *********************************************************************
  1727. * 
  1728. * CHECKNEW()
  1729. * 
  1730. * Called by:
  1731. *     MRUN210H:  cfgbbs(), cfgprompts(), cfgmaildoor(), 
  1732. *                   addgetsend(), adddlfile(), addulfile(),
  1733. *                   addsendcmd(), addscript()
  1734. * 
  1735. * Returns 0 if the current mailrun is empty; else returns 1.
  1736. * 
  1737. *********************************************************************
  1738. #endcomment
  1739.  
  1740. func checknew : integer
  1741.     if NULLSTR TaskItem
  1742.         usermsg "You must add a BBS before selecting this function!"
  1743.         return 0
  1744.     else
  1745.         return 1
  1746.     endif
  1747. endfunc
  1748.  
  1749.  
  1750. #comment
  1751. *********************************************************************
  1752. * 
  1753. * MENUDIM()
  1754. * 
  1755. * Called by:
  1756. *     MRUN210H:  callscript()
  1757. *     MRUN210B-G:  main()
  1758. * 
  1759. * Enables all menu controls, then disables those which
  1760. * cannot be used in the current module.
  1761. * 
  1762. *********************************************************************
  1763. #endcomment
  1764.  
  1765. proc menudim
  1766.     enable MENU 1 32
  1767. #ifndef MRUN210AG
  1768.     disable MENU 3 5
  1769.     disable MENU 8 11
  1770. #endif
  1771. #ifdef MRUN210G
  1772.     disable MENU 1
  1773.     disable MENU 3
  1774.     disable MENU 5 6
  1775. #endif
  1776. endproc
  1777.  
  1778.  
  1779. #comment
  1780. *********************************************************************
  1781. * 
  1782. * SORTIDX()
  1783. * 
  1784. * Calls fieldcompare(), makefullname(), openfile(),
  1785. * interfaceoff(), interfaceon()
  1786. * 
  1787. * Called by:
  1788. *     MRUN210D:  main(), getnewfiles()
  1789. *     MRUN210E:  main(), getulfiles(), updateudx()
  1790. * 
  1791. * Sorts an index file for display in the upload or download
  1792. * dialog box.  This routine uses two temp files to sort the
  1793. * contents of the referenced file.  It is used to sort an
  1794. * index file that has not been previously sorted.  The
  1795. * method used is too slow when only a couple of new items
  1796. * need to be sorted in the file.
  1797. * 
  1798. *********************************************************************
  1799. #endcomment
  1800.  
  1801. #ifdef MRUN210DE
  1802. proc sortidx
  1803. strparm idxName
  1804. intparm SortField
  1805. string temp1, temp2, Line1, Line2, LastLine
  1806. integer Unsorted, Readidx, Writeidx, i, counter
  1807.     SortField -=2
  1808.     if SortField < 0
  1809.         return
  1810.     endif
  1811.     interfaceoff()
  1812.     counter = 0
  1813.     temp1 = makefullname(TempDir, "temp1.tmp")
  1814.     temp2 = makefullname(TempDir, "temp2.tmp")
  1815.     Unsorted = 0
  1816.     Readidx = 1
  1817.     Writeidx = 2
  1818.     openfile(Unsorted, idxName, _READWRITE, _TEXT)
  1819.     fgets Unsorted Line1
  1820.     statmsg "Sorting...     %d" counter
  1821.     if feof Unsorted
  1822.         ;if the index is empty, return
  1823.         fclose Unsorted
  1824.         interfaceon()
  1825.         return
  1826.     else
  1827.         ;otherwise, open temp files and sort
  1828.         openfile(Readidx, temp1, _CREATE, _TEXT)
  1829.         openfile(Writeidx, temp2, _CREATE, _TEXT)
  1830.         ;put the first line into the read file
  1831.         fputs Readidx Line1
  1832.         rewind Readidx
  1833.         ;get the next line of the unsorted file
  1834.         fgets Unsorted Line1
  1835.         counter++
  1836.         statmsg "Sorting...     %d" counter
  1837.         fgets Readidx Line2
  1838.         if feof Unsorted
  1839.             ;prevents a single file from being deleted
  1840.             fputs Writeidx Line2
  1841.         endif
  1842.         while not feof Unsorted
  1843.             while not feof Readidx
  1844.                 if fieldcompare(Line1, Line2, SortField)
  1845.                     exitwhile
  1846.                 endif
  1847.                 fputs Writeidx Line2
  1848.                 fgets Readidx Line2
  1849.             endwhile
  1850.             fputs Writeidx Line1
  1851.             LastLine = Line1
  1852.             fgets Unsorted Line1
  1853.             counter++
  1854.             statmsg "Sorting...     %d" counter
  1855.             if feof Unsorted
  1856.                 while not feof Readidx
  1857.                     fputs Writeidx Line2
  1858.                     fgets Readidx Line2
  1859.                 endwhile
  1860.                 exitwhile
  1861.             elseif !(fieldcompare(Line1, LastLine, SortField))
  1862.                 loopwhile
  1863.             endif
  1864.             while not feof Readidx
  1865.                 fputs Writeidx Line2
  1866.                 fgets Readidx Line2
  1867.             endwhile
  1868.             rewind Readidx
  1869.             rewind Writeidx
  1870.             i = Readidx
  1871.             Readidx = Writeidx
  1872.             Writeidx = i
  1873.             fgets Readidx Line2
  1874.         endwhile
  1875.         fclose Unsorted
  1876.         fclose Readidx
  1877.         fclose Writeidx
  1878.         delfile idxName
  1879.         if Writeidx == 1
  1880.             copyfile temp1 idxName
  1881.         else
  1882.             copyfile temp2 idxName
  1883.         endif
  1884.         delfile temp1
  1885.         delfile temp2
  1886.     endif
  1887.     statmsg ""
  1888.     interfaceon()
  1889. endproc
  1890. #endif
  1891.  
  1892.  
  1893. #comment
  1894. *********************************************************************
  1895. * 
  1896. * FIELDCOMPARE()
  1897. * 
  1898. * Called by:
  1899. *     MRUN210H:  sortidx()
  1900. * 
  1901. * Compares two fields.  Returns 0 if Field1 > Field2,
  1902. * 1 if Field1 <= Field2.
  1903. * 
  1904. *********************************************************************
  1905. #endcomment
  1906.  
  1907. #ifdef MRUN210DE
  1908. func fieldcompare : integer
  1909. strparm Line1, Line2
  1910. intparm FieldType
  1911. string Field1, Field2
  1912. long number1, number2, Date1, Date2
  1913.     strextract Field1 Line1 "`t" FieldType
  1914.     strextract Field2 Line2 "`t" FieldType
  1915.     switch FieldType
  1916.         case ALPHA
  1917.             strcmpi Field1 Field2
  1918.             if $STRCMP >= 0
  1919.                 return 0
  1920.             else
  1921.                 return 1
  1922.             endif
  1923.         endcase
  1924.         case NUMERIC
  1925.             atol Field1 number1
  1926.             atol Field2 number2
  1927.             if number1 >= number2
  1928.                 return 0
  1929.             else
  1930.                 return 1
  1931.             endif
  1932.         endcase
  1933.         case MMDDYY
  1934.             strsltime Field1 "00:00:00" Date1
  1935.             strsltime Field2 "00:00:00" Date2
  1936.             if Date1 >= Date2
  1937.                 return 0
  1938.             else
  1939.                 return 1
  1940.             endif
  1941.         endcase
  1942.     endswitch
  1943. endfunc
  1944. #endif
  1945.  
  1946.  
  1947. #comment
  1948. *********************************************************************
  1949. * 
  1950. * FINDSTRING()
  1951. * 
  1952. * Called by:
  1953. *     MRUN210B:  main()
  1954. *     MRUN210C:  exportprompts()
  1955. *     MRUN210D:  getnewfiles(), import()
  1956. *     MRUN210E:  shortdesc()
  1957. *     MRUN210G:  main(), checkcommandprompt(), getconfprompt(),
  1958. *                   checkmailprompt(), checkdescprompt(), 
  1959. *                   checkbaseset(), getotherprompt(), sendmail(),
  1960. *                   getmail(), checkmail(), ulfile(), checkverifyprompt(),
  1961. *                   senddesc(), dlfile(), sendcommand(), sendscript()
  1962. * 
  1963. * Returns a value of 1 if the second string is contained
  1964. * in the first string; otherwise returns 0.
  1965. * 
  1966. *********************************************************************
  1967. #endcomment
  1968.  
  1969. #ifndef MRUN210A
  1970. #ifndef MRUN210F
  1971. func findstring : integer
  1972. strparm String1, String2
  1973. integer i = 0
  1974.     if not NULLSTR String2
  1975.         if strfind String1 String2
  1976.             i = 1
  1977.         endif
  1978.     endif
  1979.     return i
  1980. endfunc
  1981. #endif
  1982. #endif
  1983.  
  1984.  
  1985. #comment
  1986. **************************************************************************
  1987. **************************************************************************
  1988. * 
  1989. * The following routines comprise the user interface of MailRun.
  1990. * parsedialog controls the behavior of the main mailrun dialog box,
  1991. * parsemenu() controls the menu and parseobject() controls the
  1992. * toolbar.  The menus and toolbar are defined in MRUN210A in the
  1993. * procedures mrunmenu(), which creates the main menu system, 
  1994. * runmenu(), which creates the alternate menu used when a mailrun
  1995. * is executing, and mrunwin(), which creates the toolbar.
  1996. * 
  1997. **************************************************************************
  1998. **************************************************************************
  1999. #comment
  2000.  
  2001.  
  2002. #comment
  2003. *********************************************************************
  2004. * 
  2005. * INTERFACEON()
  2006. * 
  2007. * Calls parsemenu(), parseobject()
  2008. * 
  2009. * Called by:
  2010. *     MRUN210H:  sortidx(), taskfileend()
  2011. *     MRUN210A:  main()
  2012. *     MRUN210B:  main()
  2013. *     MRUN210C:  changeuserinfo(), changeprompts(), changemaildoor()
  2014. *     MRUN210D:  main(), purgeoldfiles(), getnewfiles(), deldlfile()
  2015. *     MRUN210E:  main(), insertulfile(), getulfiles(), updateudx(),
  2016. *     MRUN210F:  addgetmail(), addsendcommand(), adddoscript()
  2017. *     MRUN210G:  makequeue(), getdialstring(), senddesc(), putdesc()
  2018. * 
  2019. * Activate and deactivate the menu and iconbar.
  2020. * 
  2021. *********************************************************************
  2022. #endcomment
  2023.  
  2024. proc interfaceon
  2025.     when menu call parsemenu
  2026.     when object call parseobject
  2027. endproc
  2028.  
  2029.  
  2030. #comment
  2031. *********************************************************************
  2032. * 
  2033. * INTERFACEOFF()
  2034. * 
  2035. * Called by:
  2036. *     MRUN210H:  sortidx(), taskfilefwd()
  2037. *     MRUN210D:  main(), purgeoldfiles(), getnewfiles(), deldlfile()
  2038. *     MRUN210E:  insertulfile(), geulfiles(), updateudx()
  2039. *     MRUN210G:  makequeue(), getdialstring(), senddesc(), putdesc()
  2040. * 
  2041. * Activate and deactivate the menu and iconbar.
  2042. * 
  2043. *********************************************************************
  2044. #endcomment
  2045.  
  2046. #ifndef MRUN210BC
  2047. #ifndef MRUN210F
  2048. proc interfaceoff
  2049.     clearwhen menu
  2050.     clearwhen object
  2051. endproc
  2052. #endif
  2053. #endif
  2054.  
  2055.  
  2056. #comment
  2057. *********************************************************************
  2058. * 
  2059. * PARSEDIALOG()
  2060. * 
  2061. * Calls changestatus(), changemailrun(), maketasklist(),
  2062. * getfirstitem(), gettaskstring(), getbbsi(), getitemi(),
  2063. * swapbbs(), swapitem()
  2064. * 
  2065. * Called by
  2066. *  MRUN210A:  main(), executor()
  2067. *  MRUN210G:  main()
  2068. * 
  2069. * Checks for dialog box selection and dispatches the
  2070. * appropriate task.
  2071. * 
  2072. *********************************************************************
  2073. #endcomment
  2074.  
  2075. #ifdef MRUN210AG
  2076. proc parsedialog
  2077. integer dialogstatus, i, j, k
  2078. #ifdef MRUN210G
  2079. string LastBBS, LastItem
  2080.     LastBBS = BBS
  2081.     LastItem = Item
  2082. #endif
  2083.     dialogstatus = $DIALOG
  2084.     switch dialogstatus
  2085.         case 10
  2086.             ;User double clicked on an item
  2087.             changestatus()
  2088.             updatedlg 80
  2089.         endcase
  2090.         case 11
  2091.             ;User selected Alt-U to move an item up
  2092.             i = getbbsi()
  2093.             j = getitemi()
  2094.             if j == 0
  2095.                 ;if the selected TaskItem is a BBS
  2096.                 k = i - 1
  2097.                 swapbbs(i, k)
  2098.             else
  2099.                 ;if the selected TaskItem is an Item
  2100.                 j--
  2101.                 if swapitem(i, j)
  2102.                     TaskItem = gettaskstring(i, j)
  2103.                 endif
  2104.             endif
  2105.             updatedlg 80
  2106.         endcase
  2107.         case 12
  2108.             ;User selected Alt-I to move an item down
  2109.             i = getbbsi()
  2110.             j = getitemi()
  2111.             if j == 0
  2112.                 ;If the selected TaskItem is a BBS
  2113.                 k = i + 1
  2114.                 swapbbs(i, k)
  2115.             else
  2116.                 ;If the selected TaskItem is an Item
  2117.                 if swapitem(i, j)
  2118.                     j++
  2119.                     TaskItem = gettaskstring(i, j)
  2120.                 endif
  2121.             endif
  2122.             updatedlg 80
  2123.         endcase
  2124. #ifdef MRUN210A
  2125.         case 170
  2126.             ;User changed mailruns with combobox
  2127.             changemailrun()
  2128.             maketasklist()
  2129.             getfirstitem()
  2130.             updatedlg 80
  2131.         endcase
  2132. #endif
  2133.     endswitch
  2134. #ifdef MRUN210G
  2135.     makequeue()
  2136.     BBS = LastBBS
  2137.     Item = LastItem
  2138. #endif
  2139. endproc
  2140. #endif
  2141.  
  2142.  
  2143. #comment
  2144. *********************************************************************
  2145. * 
  2146. * SWAPBBS()
  2147. * 
  2148. * Calls readbbs(), writebbs(), maketasklist()
  2149. * 
  2150. * Called by:
  2151. *  MRUN210H: parsedialog()
  2152. * 
  2153. * Swaps two BBSs in the task list.
  2154. * 
  2155. *********************************************************************
  2156. #endcomment
  2157.  
  2158. #ifdef MRUN210AG
  2159. proc swapbbs
  2160. intparm i, k
  2161. string OldBBS, BBSNamen
  2162.     OldBBS = readbbs(k)
  2163.     if not NULLSTR OldBBS
  2164.         ;Unless this is the last (or first) BBS, swap with the next BBS
  2165.         writebbs(i, OldBBS)
  2166.         writebbs(k, BBS)
  2167.         maketasklist()
  2168.         profilerd MailRun BBS "BBSName" BBSNamen
  2169.         strfmt TaskItem "%s`t`t`t%d`t%d" BBSNamen k 0
  2170.     endif
  2171. endproc
  2172. #endif
  2173.  
  2174.  
  2175. #comment
  2176. *********************************************************************
  2177. * 
  2178. * SWAPITEM()
  2179. * 
  2180. * Calls readitem(), writeitem(), gettaskstring(), taskfilefwd(),
  2181. * taskfileend()
  2182. * 
  2183. * Called by:
  2184. *  MRUN210H: parsedialog()
  2185. * 
  2186. * Swaps two Items in the task list.
  2187. * 
  2188. *********************************************************************
  2189. #endcomment
  2190.  
  2191. #ifdef MRUN210AG
  2192. func swapitem : integer
  2193. intparm i, j
  2194. string Itemj, Iteml, TaskString
  2195. integer l
  2196.     l = j + 1
  2197.     Itemj = readitem(j)
  2198.     Iteml = readitem(l)
  2199.     if j == 0
  2200.         return 0
  2201.     endif
  2202.     if not NULLSTR Iteml
  2203.         ;Unless this is the last Item, swap with the next Item
  2204.         taskfilefwd(i, j)
  2205.         writeitem(j, Iteml)
  2206.         writeitem(l, Itemj)
  2207.         TaskString = gettaskstring(i, j)
  2208.         fputs TaskFile TaskString
  2209.         TaskString = gettaskstring(i, l)
  2210.         fputs TaskFile TaskString
  2211.         fgets OldTaskFile TaskString
  2212.         taskfileend()
  2213.         return 1
  2214.     else
  2215.         return 0
  2216.     endif
  2217. endfunc
  2218. #endif
  2219.  
  2220.  
  2221. #comment
  2222. *********************************************************************
  2223. * 
  2224. * CHANGESTATUS()
  2225. * 
  2226. * Calls getbbsi(), getitemi(), readitem(), writeitem(),
  2227. * maketasklist(), gettaskstring(), checkpending(), taskfilefwd()
  2228. * taskfileend()
  2229. * 
  2230. * Called by:
  2231. *     MRUN210H:  parsedialog()
  2232. * 
  2233. * Changes the pending/complete permanent/temporary status
  2234. * of the selected item on the task list.  Responds to user
  2235. * double-clicking on the item.
  2236. * 
  2237. *********************************************************************
  2238. #endcomment
  2239.  
  2240. #ifdef MRUN210AG
  2241. proc changestatus
  2242. string Pending, Perm, BBSNamen
  2243. integer i, j, ItemC, ItemE, ItemR
  2244.     i = getbbsi()
  2245.     j = getitemi()
  2246.     if j == 0
  2247.         ;If the item is a BBS
  2248.         ;Check for pending items
  2249.         Pending = checkpending()
  2250.         if strcmpi Pending "0"
  2251.             ;If no items are pending, set all to pending status
  2252.             Pending = "1"
  2253.         else
  2254.             ;If at least one item is pending, set all to completed status
  2255.             Pending = "0"
  2256.         endif
  2257.         j = 1
  2258.         Item = readitem(j)
  2259.         ;Update all items
  2260.         while not NULLSTR Item
  2261.             strupdt Item Pending 0 1
  2262.             writeitem(j, Item)
  2263.             j++
  2264.             Item = readitem(j)
  2265.         endwhile
  2266.         maketasklist()
  2267.         profilerd MailRun BBS "BBSName" BBSNamen
  2268.         strfmt TaskItem "%s`t`t`t%d`t%d" BBSNamen i 0
  2269.     else
  2270.         ;If it is not a BBS
  2271.         Item = readitem(j)
  2272.         atoi ItemComplete ItemC
  2273.         atoi ItemRemaining ItemR
  2274.         atoi ItemError ItemE
  2275.         strextract Pending Item "," 0
  2276.         strextract Perm Item "," 1
  2277.         if not strcmpi Pending "1"
  2278.             if strcmpi Pending "0"
  2279.                 ItemC--
  2280.             else
  2281.                 ItemE--
  2282.             endif
  2283.             ItemR++
  2284.             Pending = "1"
  2285.             Perm = "0"
  2286.         else
  2287.             if strcmpi Perm "0"
  2288.                 Perm = "1"
  2289.             else
  2290.                 Pending = "0"
  2291.                 ItemC++
  2292.                 ItemR--
  2293.             endif
  2294.         endif
  2295.         itoa ItemC ItemComplete
  2296.         itoa ItemR ItemRemaining
  2297.         itoa ItemE ItemError
  2298.         strupdt Item Pending 0 1
  2299.         strupdt Item Perm 2 1
  2300.         taskfilefwd(i, j)
  2301.         writeitem(j, Item)
  2302.         TaskItem = gettaskstring(i, j)
  2303.         fputs TaskFile TaskItem
  2304.         taskfileend()
  2305.     endif
  2306. endproc
  2307. #endif
  2308.  
  2309.  
  2310. #comment
  2311. *********************************************************************
  2312. *
  2313. * TASKFILEFWD()
  2314. *
  2315. * Calls makefullname(), openfile(), interfaceoff()
  2316. *
  2317. * Called by:
  2318. *  MRUN210H:  swapitem(), changestatus()
  2319. *
  2320. * Opens the Task List file and moves forward to the designated
  2321. * coordinates.
  2322. * 
  2323. *********************************************************************
  2324. #endcomment
  2325.  
  2326. #ifdef MRUN210AG
  2327. proc taskfilefwd
  2328. intparm i, j
  2329. string OldTasks, OldTaskString, TaskString
  2330.     interfaceoff()
  2331.     OldTasks = makefullname(TempDir, "oldtasks.tmp")
  2332.     copyfile TaskList OldTasks
  2333.     openfile(OldTaskFile, OldTasks, _READWRITE, _TEXT)
  2334.     openfile(TaskFile, TaskList, _CREATE, _TEXT)
  2335.     OldTaskString = gettaskstring(i, j)
  2336.     fgets OldTaskFile TaskString
  2337.     while not strcmpi OldTaskString TaskString
  2338.         fputs TaskFile TaskString
  2339.         fgets OldTaskFile TaskString
  2340.     endwhile
  2341. endproc
  2342. #endif
  2343.  
  2344.  
  2345. #comment
  2346. *********************************************************************
  2347. *
  2348. * TASKFILEEND()
  2349. *
  2350. * Calls makefullname(), interfaceon()
  2351. *
  2352. * Called by:
  2353. *  MRUN210H:  swapitem(), changestatus()
  2354. *
  2355. * Reads to the end of the Task List file and closes it.
  2356. * 
  2357. *********************************************************************
  2358. #endcomment
  2359.  
  2360. #ifdef MRUN210AG
  2361. proc taskfileend
  2362. string TaskString, OldTasks
  2363.     fgets OldTaskFile TaskString
  2364.     while not feof OldTaskFile
  2365.         fputs TaskFile TaskString
  2366.         fgets OldTaskFile TaskString
  2367.     endwhile
  2368.     fclose OldTaskFile
  2369.     fclose TaskFile
  2370.     OldTasks = makefullname(TempDir, "oldtasks.tmp")
  2371.     delfile OldTasks
  2372.     interfaceon()
  2373. endproc
  2374. #endif
  2375.  
  2376.  
  2377. #comment
  2378. *********************************************************************
  2379. * 
  2380. * PARSEMENU()
  2381. * 
  2382. * Calls filenewmrun(), filesave(), filesaveas(), filereset(),
  2383. * filedelmrun(), fileautorun(), fileexit(), editcut(), editcopy(), 
  2384. * editpaste(), editdelete(), cfgmrun(), cfgbbs(), cfgprompts(), 
  2385. * cfgmaildoor(), defaultsmailrun(), defaultsbbs(), defaultsprompts(),
  2386. * defaultsdoor(), addnewbbs(), addgetsend(), addupload(),
  2387. * adddownload(), addsendcmd(), addscript(), executemailrun(),
  2388. * executeqwkreader(), executearchiver(), executelogviewer(),
  2389. * helpcontents(), helpcontext(), helpabout()
  2390. * 
  2391. * Called by:
  2392. *     MRUN210H:  interfaceon()
  2393. * 
  2394. * Parses a selection from the MailRun menu.
  2395. * 
  2396. *********************************************************************
  2397. #endcomment
  2398.  
  2399. proc parsemenu
  2400. integer menustatus
  2401.     menustatus = $MENU
  2402.     switch menustatus
  2403. #ifndef MRUN210G
  2404.         case 1
  2405.             ;User selected file.new
  2406.             filenewmrun()
  2407.         endcase
  2408. #endif
  2409.         case 2
  2410.             ;User selected file.save
  2411.             filesave()
  2412.         endcase
  2413. #ifdef MRUN210A
  2414.         case 3
  2415.             ;User selected file.save_as
  2416.             filesaveas()
  2417.         endcase
  2418. #endif
  2419. #ifdef MRUN210AG
  2420.         case 4
  2421.             ;User selected file.reset
  2422.             filereset()
  2423.         endcase
  2424. #endif
  2425. #ifdef MRUN210A
  2426.         case 5
  2427.             ;User selected file.delete_mailrun
  2428.             filedelmrun()
  2429.         endcase
  2430. #endif
  2431. #ifndef MRUN210G
  2432.         case 6
  2433.             ;User selected file.create_autorun
  2434.             fileautorun()
  2435.         endcase
  2436. #endif
  2437.         case 7
  2438.             ;User selected file.exit
  2439.             fileexit()
  2440.         endcase
  2441. #ifdef MRUN210AG
  2442.         case 8
  2443.             ;User selected edit.cut
  2444.             editcut()
  2445.         endcase
  2446.         case 9
  2447.             ;User selected edit.copy
  2448.             editcopy()
  2449.         endcase
  2450.         case 10
  2451.             ;User selected edit.paste
  2452.             editpaste()
  2453.         endcase
  2454.         case 11
  2455.             ;User selected delete_item
  2456.             editdelete()
  2457.         endcase
  2458. #endif
  2459.         case 12
  2460.             ;User selected configure.mailrun_settings
  2461.             cfgmrun()
  2462.         endcase
  2463.         case 13
  2464.             ;User selected configure.bbs_settings
  2465.             cfgbbs()
  2466.         endcase
  2467.         case 14
  2468.             ;User selected configure.bbs_prompts
  2469.             cfgprompts()
  2470.         endcase
  2471.         case 15
  2472.             ;User selected configure.bbs_mail_door
  2473.             cfgmaildoor()
  2474.         endcase
  2475.         case 16
  2476.             ;User selected configure.defaults.mailrun
  2477.             defaultsmailrun()
  2478.         endcase
  2479.         case 17
  2480.             ;User selected configure.defaults.bbs
  2481.             defaultsbbs()
  2482.         endcase
  2483.         case 18
  2484.             ;User selected configure.defaults.prompts
  2485.             defaultsprompts()
  2486.         endcase
  2487.         case 19
  2488.             ;User selected configure.defaults.maildoor
  2489.             defaultsdoor()
  2490.         endcase
  2491.         case 20
  2492.             ;User selected add.new_bbs
  2493.             addnewbbs()
  2494.         endcase
  2495.         case 21
  2496.             ;User selected add.get/send_mail
  2497.             addgetsend()
  2498.         endcase
  2499.         case 22
  2500.             ;User selected add.upload_file
  2501.             addupload()
  2502.         endcase
  2503.         case 23
  2504.             ;User selected add.download_file
  2505.             adddownload()
  2506.         endcase
  2507.         case 24
  2508.             ;User selected add.send_command
  2509.             addsendcmd()
  2510.         endcase
  2511.         case 25
  2512.             ;User selected add.execute_script
  2513.             addscript()
  2514.         endcase
  2515.         case 26
  2516.             ;User selected execute.mailrun
  2517.             executemailrun()
  2518.         endcase
  2519.         case 27
  2520.             ;User selected execute.qwk_reader
  2521.             executeqwkreader()
  2522.         endcase
  2523.         case 28
  2524.             ;User selected execute.archiver
  2525.             executearchiver()
  2526.         endcase
  2527.         case 29
  2528.             ;User selected execute.view_log_file
  2529.             executelogviewer()
  2530.         endcase
  2531.         case 30
  2532.             ;User selected help.contents
  2533.             helpcontents()
  2534.         endcase
  2535.         case 31
  2536.             ;User selected help.current_window
  2537.             helpcontext()
  2538.         endcase
  2539.         case 32
  2540.             ;User selected help.about
  2541.             helpabout()
  2542.         endcase
  2543.     endswitch
  2544. endproc
  2545.  
  2546.  
  2547. #comment
  2548. *********************************************************************
  2549. * 
  2550. * PARSEOBJECT()
  2551. * 
  2552. * Calls executemailrun(), filereset(), filenewmrun(), 
  2553. * cfgbbs(), addnewbbs(), addgetsend(), addupload(),
  2554. * adddownload(), addsendcmd(), addscript(), editdelete(),
  2555. * executelogviewer(), executeqwkreader(), executearchiver(), 
  2556. * fileexit(), helpabout()
  2557. * 
  2558. * Called by:
  2559. *     MRUN210H:  interfaceon()
  2560. * 
  2561. * Parses a selection from the MailRun icon bar.
  2562. * 
  2563. *********************************************************************
  2564. #endcomment
  2565.  
  2566. proc parseobject
  2567. integer objectstatus
  2568.     objectstatus = $OBJECT
  2569.     switch objectstatus
  2570.         case 1
  2571.             ;User selected icon for execute.mailrun
  2572.             executemailrun()
  2573.         endcase
  2574. #ifdef MRUN210AG
  2575.         case 2
  2576.             ;User selected icon for file.reset
  2577.             filereset()
  2578.         endcase
  2579. #endif
  2580. #ifndef MRUN210G
  2581.         case 3
  2582.             ;User selected icon for file.new
  2583.             filenewmrun()
  2584.         endcase
  2585. #endif
  2586.         case 4
  2587.             ;User selected icon for configure.bbs
  2588.             cfgbbs()
  2589.         endcase
  2590.         case 5
  2591.             ;User selected icon for add.new_bbs
  2592.             addnewbbs()
  2593.         endcase
  2594.         case 6
  2595.             ;User selected icon for add.get/send_mail
  2596.             addgetsend()
  2597.         endcase
  2598.         case 7
  2599.             ;User selected icon for add.upload_file
  2600.             addupload()
  2601.         endcase
  2602.         case 8
  2603.             ;User selected icon for add.download_file
  2604.             adddownload()
  2605.         endcase
  2606.         case 9
  2607.             ;User selected icon for add.send_command
  2608.             addsendcmd()
  2609.         endcase
  2610.         case 10
  2611.             ;User selected icon for add.execute_script
  2612.             addscript()
  2613.         endcase
  2614. #ifdef MRUN210AG
  2615.         case 11
  2616.             ;User selected icon for file.delete_item
  2617.             editdelete()
  2618.         endcase
  2619. #endif
  2620.         case 12
  2621.             ;User selected icon for execute.view_log_file
  2622.             executelogviewer()
  2623.         endcase
  2624.         case 13
  2625.             ;User selected icon for execute.qwk_reader
  2626.             executeqwkreader()
  2627.         endcase
  2628.         case 14
  2629.             ;User selected icon for execute.archiver
  2630.             executearchiver()
  2631.         endcase
  2632.         case 15
  2633.             ;User selected icon for file.exit
  2634.             fileexit()
  2635.         endcase
  2636.         case 16
  2637.             ;User selected icon for context sensitive help
  2638.             helpcontext()
  2639.         endcase
  2640.     endswitch
  2641. endproc
  2642.  
  2643.  
  2644. #comment
  2645. **************************************************************************
  2646. **************************************************************************
  2647. * 
  2648. * The following procedures correspond to menu selections
  2649. * and are called from parsemenu() and parseobject().
  2650. * 
  2651. **************************************************************************
  2652. **************************************************************************
  2653. #endcomment
  2654.  
  2655.  
  2656. #comment
  2657. *********************************************************************
  2658. * 
  2659. * FILENEWMRUN()
  2660. * 
  2661. * Calls checkrunning(), checkchanged(), makefullname(),
  2662. * callscript(), MRUN210B\main()
  2663. * 
  2664. * Called by:
  2665. *     MRUN210H:  parsemenu(), parseobject()
  2666. *     
  2667. * Corresponds to File.New_MailRun menu selection.  Creates a 
  2668. * new mailrun.
  2669. *     
  2670. *********************************************************************
  2671. #endcomment
  2672.  
  2673. #ifndef MRUN210G
  2674. proc filenewmrun
  2675. #ifndef MRUN210B
  2676. string changesettings
  2677. #endif
  2678.     if checkrunning() && checkchanged()
  2679.         FLAGS = NEW
  2680. #ifndef MRUN210B
  2681.         changesettings = makefullname(MailRunDir, "MRUN210B")
  2682.         callscript(changesettings)
  2683. #else
  2684.         main()
  2685. #endif
  2686.     endif
  2687. endproc
  2688. #endif
  2689.  
  2690.  
  2691. #comment
  2692. *********************************************************************
  2693. * 
  2694. * FILESAVE()
  2695. * 
  2696. * Calls makefullname()
  2697. * 
  2698. * Called by:
  2699. *     MRUN210H:  parsemenu(), makemrn(), changemailrun(), fileexit()
  2700. *     MRUN210B:  newmailrun()
  2701. * 
  2702. * Corresponds to the File.Save menu selection.  Saves the 
  2703. * current mailrun.
  2704. *     
  2705. *********************************************************************
  2706. #endcomment
  2707.  
  2708. proc filesave
  2709. string LastRun
  2710.     if !(FLAGS & DEFAULTS)
  2711.         findfirst MailRun
  2712.         LastRun = makefullname(MailRunDir, $FILENAME)
  2713.         if not NULLSTR $FILENAME
  2714.             delfile LastRun
  2715.         endif
  2716.         copyfile MailRun LastRun
  2717.         profilewr MailRunIni "MailRun" "MailRun" $FILENAME
  2718.     endif
  2719. endproc
  2720.  
  2721.  
  2722. #comment
  2723. *********************************************************************
  2724. * 
  2725. * FILESAVEAS()
  2726. * 
  2727. * Calls fverify(), makefullname(), copymrn(), makemailrunlist()
  2728. * 
  2729. * Called by:
  2730. *     MRUN210H:  parsemenu()
  2731. * 
  2732. * Corresponds to the File.Save_AS menu selection.  Saves the
  2733. * current mailrun under a new name and makes the new mailrun
  2734. * current.
  2735. * 
  2736. *********************************************************************
  2737. #endcomment
  2738.  
  2739. #ifdef MRUN210A
  2740. proc filesaveas
  2741. string NewRun, temp
  2742. integer Response
  2743.     ;Make sure the entered MailRun ID is the correct length
  2744.     ;and that it doesn't already exist
  2745.     while 1
  2746.         NewRun = ""
  2747.         sdlginput "New MailRun" \
  2748.             "Save the current mailrun as:" NewRun
  2749.         if FAILURE
  2750.             exit
  2751.         endif
  2752.         strlwr NewRun
  2753.         if not fverify(NewRun)
  2754.             usermsg \
  2755.             "A mailrun ID must be a valid DOS file name without the extension."
  2756.             loopwhile
  2757.         endif
  2758.         strfmt temp "%s.mrn" NewRun
  2759.         NewRun = makefullname(MailRunDir, temp)
  2760.         if isfile NewRun
  2761.             sdlgmsgbox "MailRun Message" \
  2762.                 "%s already exists!`r`n`r`nReplace it?" QUESTION YESNO Response 2
  2763.             if Response == 7
  2764.                 ;if user selected "No"
  2765.                 NewRun = ""
  2766.                 loopwhile
  2767.             endif
  2768.         endif
  2769.         exitwhile
  2770.     endwhile
  2771.     delfile NewRun
  2772.     MailRunTrunc = temp
  2773.     copyfile MailRun NewRun
  2774.     copymrn()
  2775.     makemailrunlist()
  2776.     updatedlg 512
  2777. endproc
  2778. #endif
  2779.  
  2780.  
  2781. #comment
  2782. *********************************************************************
  2783. * 
  2784. * FILERESET()
  2785. * 
  2786. * Calls maketasklist(), getfirstitem(), readbbs(), readitem(),
  2787. * writeitem()
  2788. * 
  2789. * Called by:
  2790. *     MRUN210H:  parsemenu(), parseobject(), filereset()
  2791. * 
  2792. * Corresponds to the File.Reset_MailRun menu selection.
  2793. * Resets completed permenant items to pending.  Deletes
  2794. * completed temporary items.
  2795. * 
  2796. *********************************************************************
  2797. #endcomment
  2798.  
  2799. #ifdef MRUN210AG
  2800. proc filereset
  2801. string Pending, Perm
  2802. integer p1, p2, i, j, k
  2803.     i = 1
  2804.     BBS = readbbs(i)
  2805.     ;Loop through each BBS
  2806.     while not NULLSTR BBS
  2807.         j = 1
  2808.         k = 1
  2809.         Item = readitem(j)
  2810.         ;Loop through each Item
  2811.         while not NULLSTR Item
  2812.             ;Clear the old item
  2813.             writeitem(j, "")
  2814.             strextract pending Item "," 0
  2815.             strextract perm Item "," 1
  2816.             atoi pending p1
  2817.             atoi perm p2
  2818.  
  2819.             ;Items that are completed and temporary will not be updated
  2820.             ;The second counter "k" is required to avoid gaps where items
  2821.             ;are deleted.
  2822.  
  2823.             if (p1 != 0) || (p2 != 0)
  2824.                 strupdt Item "1" 0 1
  2825.                 writeitem(k, Item)
  2826.                 k++
  2827.             endif
  2828.             j++
  2829.             Item = readitem(j)
  2830.         endwhile
  2831.         i++
  2832.         BBS = readbbs(i)
  2833.     endwhile
  2834.     maketasklist()
  2835.     getfirstitem()
  2836.     updatedlg 80
  2837. endproc
  2838. #endif
  2839.  
  2840.  
  2841. #comment
  2842. *********************************************************************
  2843. * 
  2844. * FILEDELMRUN()
  2845. * 
  2846. * Calls makefullname(), copymrn(), makemailrunlist(),
  2847. * maketasklist(), getfirstitem()
  2848. * 
  2849. * Called by:
  2850. *     MRUN210H:  parsemenu()
  2851. * 
  2852. * Corresponds to the File.Delete_MailRun menu selection.
  2853. * Deletes the current mailrun and makes the next available
  2854. * mailrun current.
  2855. * 
  2856. *********************************************************************
  2857. #endcomment
  2858.  
  2859. #ifdef MRUN210A
  2860. proc filedelmrun
  2861. string LastMRun
  2862.     findfirst MailRun
  2863.     LastMRun = makefullname(MailRunDir, $FILENAME)
  2864.     delfile LastMRun
  2865.     LastMRun = makefullname(MailRunDir, "*.MRN")
  2866.     findfirst LastMRun
  2867.     MailRunTrunc = $FILENAME
  2868.     copymrn()
  2869.     makemailrunlist()
  2870.     maketasklist()
  2871.     getfirstitem()
  2872.     updatedlg -1
  2873. endproc
  2874. #endif
  2875.  
  2876.  
  2877. #comment
  2878. *********************************************************************
  2879. * 
  2880. * FILEAUTORUN()
  2881. * 
  2882. * Calls makefullname(), openfile()
  2883. * 
  2884. * Called by:
  2885. *     MRUN210H:  parsemenu()
  2886. * 
  2887. * Corresponds to the File.Create_AutoRun menu selection.
  2888. * Creates an AutoRun script file.
  2889. * 
  2890. *********************************************************************
  2891. #endcomment
  2892.  
  2893. #ifndef MRUN210G
  2894. proc fileautorun
  2895. string AutoRunFile
  2896.     findfirst MailRun
  2897.     AutoRunFile = makefullname(MailRunDir, $FNAME)
  2898.     strcat AutoRunFile ".WAS"
  2899.     openfile(0, AutoRunFile, _CREATE, _TEXT)
  2900.     fstrfmt 0 ";MailRun autostart script for %s`r`n`r`n" MailRunTrunc
  2901.     fputs 0 "proc main"
  2902.     fputs 0 "string MailRunIni"
  2903.     fputs 0 "`tMailRunIni = $WINPATH"
  2904.     fputs 0 "`taddfilename MailRunIni `"MAILRUN.INI`""
  2905.     fputs 0 "`tprofilewr MailRunIni `"MailRun`" `"AutoRun`" 1"
  2906.     fstrfmt 0 "`tprofilewr MailRunIni `"MailRun`" `"MailRun`" `"%s`"`r`n" \
  2907.         MailRunTrunc
  2908.     fputs 0 "`tchain `"MRUN210`""
  2909.     fputs 0 "endproc"
  2910.     fclose 0
  2911. endproc
  2912. #endif
  2913.  
  2914.  
  2915. #comment
  2916. *********************************************************************
  2917. * 
  2918. * FILEEXIT()
  2919. * 
  2920. * Calls filesave(), cleardir(), makefullname()
  2921. * 
  2922. * Called by:
  2923. *     MRUN210H:  parsemenu(), parseobject(), openfile()
  2924. *     MRUN210A:  executor()
  2925. *     MRUN210B:  changemrundir()
  2926. *     MRUN210G:  dobbs()
  2927. * 
  2928. * Corresponds to the File.Exit menu selection.  Restores
  2929. * system settings, deletes temporary files, and halts script.
  2930. * 
  2931. *********************************************************************
  2932. #endcomment
  2933.  
  2934. proc fileexit
  2935. string StateCapPath, StateCapFile, StateDnldPath, StateUpldPath
  2936. string CleanupFile
  2937. integer StateAutoDL, StateActionBar, StateMetaKeys
  2938.  
  2939.     ;Update the last mailrun
  2940.     filesave()
  2941.  
  2942.     ;Retrieve the previous system state from the cleanup file
  2943.     cleanupfile = makefullname(TempDir, "CLEANUP.TMP")
  2944.     profilerd CleanupFile "Cleanup" "StateAutoDL" StateAutoDL
  2945.     profilerd CleanupFile "Cleanup" "StateCapPath" StateCapPath
  2946.     profilerd CleanupFile "Cleanup" "StateCapFile" StateCapFile
  2947.     profilerd CleanupFile "Cleanup" "StateDnldPath" StateDnldPath
  2948.     profilerd CleanupFile "Cleanup" "StateUpldPath" StateUpldPath
  2949.     profilerd CleanupFile "Cleanup" "StateActionBar" StateActionBar
  2950.     profilerd CleanupFile "Cleanup" "StateMetaKeys" StateMetaKeys
  2951.  
  2952.     ;Restore the settings
  2953.     capture OFF
  2954.     set capture path StateCapPath
  2955.     set capture file StateCapFile
  2956.     set dnldpath StateDnldPath
  2957.     set upldpath StateUpldPath
  2958.     set aspect rangechk ON
  2959.     if StateAutoDL != 0
  2960.         set autodnld ON
  2961.     endif
  2962.     if StateActionBar != 0
  2963.         actionbar ON
  2964.     endif
  2965.     if StateMetaKeys != 0
  2966.         metakeys ON
  2967.     endif
  2968.  
  2969.     cleardir(TempDir)
  2970.     chdir MailRunDir
  2971.     rmdir TempDir
  2972.     statmsg ""
  2973.     remove USERWIN
  2974. #ifdef MRUN210A
  2975.     if PostRun == 3
  2976.         closepw
  2977.     endif
  2978. #endif
  2979.     halt
  2980. endproc
  2981.  
  2982.  
  2983. #comment
  2984. *********************************************************************
  2985. * 
  2986. * EDITCUT()
  2987. * 
  2988. * Calls editcopy(), editdelete()
  2989. * 
  2990. * Called by:
  2991. *     MRUN210H:  parsemenu()
  2992. * 
  2993. * Corresponds to the Edit.Cut menu selection.  Copies the
  2994. * current item in the Task List to the clipboard and deletes
  2995. * it from the Task List.
  2996. * 
  2997. *********************************************************************
  2998. #endcomment
  2999.  
  3000. #ifdef MRUN210AG
  3001. proc editcut
  3002.     editcopy()
  3003.     editdelete()
  3004. endproc
  3005. #endif
  3006.  
  3007.  
  3008. #comment
  3009. *********************************************************************
  3010. * 
  3011. * EDITCOPY()
  3012. * 
  3013. * Calls getbbsi(), getitemi(), makefullname(), loadbbsinfo(),
  3014. * loadprompts(), loadmaildoor(), writebbsinfo(), writeprompts(),
  3015. * writemaildoor(), readitem()
  3016. * 
  3017. * Called by:
  3018. *     MRUN210H:  parsemenu(), editcut()
  3019. * 
  3020. * Coresponds to the Edit.Copy menu selection.  Copies the 
  3021. * currently selected item in the Task List to the clipboard.
  3022. * If the item is a BBS, all user info and prompts are copied
  3023. * as well.
  3024. * 
  3025. *********************************************************************
  3026. #endcomment
  3027.  
  3028. #ifdef MRUN210AG
  3029. proc editcopy
  3030. string LastBBS, LastItem, LastMRun, temp
  3031. integer i, j
  3032.     if NULLSTR TaskItem
  3033.         return
  3034.     endif
  3035.     LastBBS = BBS
  3036.     LastItem = Item
  3037.     LastMRun = MailRun
  3038.     i = getbbsi()
  3039.     j = getitemi()
  3040.     temp = makefullname(TempDir, "TEMP.TMP")
  3041.     ;If the current TaskItem is a BBS...
  3042.     if j == 0
  3043. #ifdef MRUN210G
  3044.         usermsg "Cannot copy/cut a BBS while a mailrun is executing!"
  3045. #else
  3046.         loadbbsinfo()
  3047.         loadprompts()
  3048.         loadmaildoor()
  3049.         MailRun = temp
  3050.         profilewr temp "MailRun Data" "BBS" BBS
  3051.         writebbsinfo()
  3052.         writeprompts()
  3053.         writemaildoor()
  3054.         filetoclip TEXT temp
  3055. #endif
  3056.     else
  3057.         Item = readitem(j)
  3058.         profilewr temp "MailRun Data" "Item" Item
  3059.         filetoclip TEXT temp
  3060.     endif
  3061.     delfile temp
  3062.     MailRun = LastMRun
  3063.     BBS = LastBBS
  3064.     Item = LastItem
  3065. endproc
  3066. #endif
  3067.  
  3068.  
  3069. #comment
  3070. *********************************************************************
  3071. * 
  3072. * EDITPASTE()
  3073. * 
  3074. * Calls getbbsi(), getitemi(), makefullname(), gettaskstring(),
  3075. * insertitem(), makebbslist(), insertbbs(), loadbbsinfo(),
  3076. * loadprompts(), loadmaildoor(), writebbsinfo(), writeprompts(),
  3077. * writemaildoor(), maketasklist()
  3078. * 
  3079. * Called by:
  3080. *     MRUN210H:  parsemenu()
  3081. * 
  3082. * Corresponds to the Edit.Paste menu selection.  Pastes an
  3083. * item from the clipboard into the current mailrun.
  3084. * 
  3085. *********************************************************************
  3086. #endcomment
  3087.  
  3088. #ifdef MRUN210AG
  3089. proc editpaste
  3090. string LastBBS, LastItem, LastMRun, temp
  3091. string NewBBS, NovumItem
  3092. integer i, j
  3093.     LastMRun = MailRun
  3094.     LastBBS = BBS
  3095.     LastItem = Item
  3096.     i = getbbsi()
  3097.     j = getitemi()
  3098.     temp = makefullname(TempDir, "TEMP.TMP")
  3099.     cliptofile TEXT temp
  3100.     profilerd temp "MailRun Data" "Item" NovumItem
  3101.     profilerd temp "MailRun Data" "BBS" NewBBS
  3102.     if not NULLSTR NovumItem
  3103.         if NULLSTR TaskItem
  3104.             usermsg "You must add a BBS first!"
  3105.             return
  3106.         endif
  3107.         insertitem(j, NovumItem)
  3108.         TaskItem = gettaskstring(i, j)
  3109.     elseif not NULLSTR NewBBS
  3110. #ifdef MRUN210G
  3111.         usermsg "Cannot paste a BBS while a mailrun is executing!"
  3112. #else
  3113.         makebbslist()
  3114.         if strfind BBSList NewBBS
  3115.             errormsg "That BBS is already in the MailRun!"
  3116.             return
  3117.         endif
  3118.         if not NULLSTR BBSList
  3119.             insertbbs(i, NewBBS)
  3120.         else
  3121.             i = 0
  3122.             profilewr MailRun "MailRun" "BBS_1" NewBBS
  3123.         endif
  3124.         BBS = NewBBS
  3125.         MailRun = temp
  3126.         loadbbsinfo()
  3127.         loadprompts()
  3128.         loadmaildoor()
  3129.         MailRun = LastMRun
  3130.         writebbsinfo()
  3131.         writeprompts()
  3132.         writemaildoor()
  3133.         i++
  3134.         strfmt TaskItem "%s`t`t`t%d`t0" BBSName i
  3135. #endif
  3136.     else
  3137.         usermsg "Nothing to paste!"
  3138.         return
  3139.     endif
  3140.     BBS = LastBBS
  3141.     Item = LastItem
  3142.     maketasklist()
  3143.     updatedlg 80
  3144. endproc
  3145. #endif
  3146.  
  3147.  
  3148. #comment
  3149. *********************************************************************
  3150. * 
  3151. * EDITDELETE()
  3152. * 
  3153. * Calls getbbsi(), getitemi(), readbbs(), readitem(),
  3154. * writebbs(), writeitem(), maketasklist(), makebbslist(),
  3155. * gettaskstring()
  3156. * 
  3157. * Called by:
  3158. *     MRUN210H:  parsemenu(), parseobject(), editcut()
  3159. *     MRUN210A:  parsekeystate()
  3160. * 
  3161. * Corresponds to the Edit.Delete menu selection.  Deletes
  3162. * the currently selected item in the Task List.
  3163. * 
  3164. *********************************************************************
  3165. #endcomment
  3166.  
  3167. #ifdef MRUN210AG
  3168. proc editdelete
  3169. string BBSNamen, LastBBS, LastItem
  3170. integer i, j, k, l
  3171.     LastBBS = BBS
  3172.     LastItem = Item
  3173.     i = getbbsi()
  3174.     j = getitemi()
  3175.     if j == 0
  3176.         ;If the current TaskItem is a BBS...
  3177.         l = i
  3178.         k = l + 1
  3179.         BBS = readbbs(k)
  3180.  
  3181.         ;Decrement the BBS coordinate of each BBS after the one selected
  3182.  
  3183.         while not NULLSTR BBS
  3184.             writebbs(l, BBS)
  3185.             l++
  3186.             k++
  3187.             BBS = readbbs(k)
  3188.         endwhile
  3189.         writebbs(l, "")
  3190.         ;Update the task list
  3191.         maketasklist()
  3192.  
  3193.         ;Reset the TaskItem.  If the selected BBS was the last one
  3194.         ;in the list, set TaskItem to the previous BBS; otherwise,
  3195.         ;set it to the next BBS
  3196.  
  3197.         BBS = readbbs(i)
  3198.         if NULLSTR BBS
  3199.             i--
  3200.             BBS = readbbs(i)
  3201.             if NULLSTR BBS
  3202.                 TaskItem = ""
  3203.             else
  3204.                 profilerd MailRun BBS "BBSName" BBSNamen
  3205.                 strfmt TaskItem "%s`t`t`t%d`t%d" BBSNamen i 0
  3206.             endif
  3207.         else
  3208.             profilerd MailRun BBS "BBSName" BBSNamen
  3209.             strfmt TaskItem "%s`t`t`t%d`t%d" BBSNamen i 0
  3210.         endif
  3211.  
  3212.     else
  3213.         ;If the current TaskItem is an Item
  3214.         l = j
  3215.         k = l + 1
  3216.  
  3217.         ;Decrement the Item coordinate of each item after the one selected
  3218.  
  3219.         Item = readitem(k)
  3220.         while not NULLSTR Item
  3221.             writeitem(l, Item)
  3222.             l++
  3223.             k++
  3224.             Item = readitem(k)
  3225.         endwhile
  3226.         writeitem(l, "")
  3227.         ;Update the task list
  3228.         maketasklist()
  3229.  
  3230.         ;Reset the TaskItem to the next Item for that BBS.  If the selected
  3231.         ;Item was the last one for that BBS, set TaskItem to the previous
  3232.         ;Item.  If it was the only item for that BBS, set it to the BBS name.
  3233.  
  3234.         BBS = readbbs(i)
  3235.         Item = readitem(j)
  3236.         if not NULLSTR Item
  3237.             ;If it wasn't the last item...
  3238.             TaskItem = gettaskstring(i, j)
  3239.         elseif j == 1
  3240.             ;If it was the only item...
  3241.             profilerd MailRun BBS "BBSName" BBSNamen
  3242.             strfmt TaskItem "%s`t`t`t%d`t%d" BBSNamen i 0
  3243.         else
  3244.             ;If it was the last of multiple items...
  3245.             j--
  3246.             Item = readitem(j)
  3247.             TaskItem = gettaskstring(i, j)
  3248.         endif
  3249.     endif
  3250.     if FLAGS & RUNNING
  3251.         BBS = LastBBS
  3252.         Item = LastItem
  3253.     endif
  3254.     updatedlg 80
  3255. endproc
  3256. #endif
  3257.  
  3258.  
  3259. #comment
  3260. *********************************************************************
  3261. * 
  3262. * CFGMRUN()
  3263. * 
  3264. * Calls checkchanged(), configmrun()
  3265. * 
  3266. * Called by:
  3267. *     MRUN210H:  parsemenu()
  3268. * 
  3269. * Corresponds to the Configure.MailRun_Settings menu selection.
  3270. * 
  3271. *********************************************************************
  3272. #endcomment
  3273.  
  3274. proc cfgmrun
  3275.     if checkchanged()
  3276.         ;reset all flags except RUNNING
  3277.         FLAGS &= RUNNING
  3278.         configmrun()
  3279.     endif
  3280. endproc
  3281.  
  3282.  
  3283. #comment
  3284. *********************************************************************
  3285. * 
  3286. * DEFAULTSMAILRUN()
  3287. * 
  3288. * Calls checkchanged(), configmrun()
  3289. * 
  3290. * Called by:
  3291. *     MRUN210H:  parsemenu()
  3292. * 
  3293. * Corresponds to the Configure.Defaults.MailRun menu selection.
  3294. *     
  3295. *********************************************************************
  3296. #endcomment
  3297.  
  3298. proc defaultsmailrun
  3299. #ifdef MRUN210B
  3300.     if FLAGS & DEFAULTS
  3301.         return
  3302.     endif
  3303. #endif
  3304.     if checkchanged()
  3305.         ;reset all flags but RUNNING and set the DEFAULTS flag
  3306.         FLAGS &= RUNNING
  3307.         FLAGS |= DEFAULTS
  3308.         configmrun()
  3309.     endif
  3310. endproc
  3311.  
  3312.  
  3313. #comment
  3314. *********************************************************************
  3315. * 
  3316. * CONFIGMRUN()
  3317. * 
  3318. * Calls MRUN210B\main(), makefullname(), callscript()
  3319. * 
  3320. * Called by:
  3321. *     MRUN210H:  cfgmrun(), defaultsmailrun()
  3322. * 
  3323. * Calls the changesettings script module.
  3324. *     
  3325. *********************************************************************
  3326. #endcomment
  3327.  
  3328. proc configmrun
  3329. #ifdef MRUN210B
  3330.         main()
  3331. #else
  3332. string changesettings
  3333.         changesettings = makefullname(MailRunDir, "MRUN210B")
  3334.         callscript(changesettings)
  3335. #endif
  3336. endproc
  3337.  
  3338.  
  3339. #comment
  3340. *********************************************************************
  3341. * 
  3342. * CFGBBS()
  3343. * 
  3344. * Calls checkchanged(), checknew(), configbbs()
  3345. * 
  3346. * Called by:
  3347. *     MRUN210H:  parsemenu(), parseobject()
  3348. *     MRUN210C:  changeprompts(), changemaildoor()
  3349. * 
  3350. * Corresponds to the Configure.BBS_Settings menu selection.
  3351. * 
  3352. *********************************************************************
  3353. #endcomment
  3354.  
  3355. proc cfgbbs
  3356.     if checkchanged() && checknew()
  3357.         FLAGS &= RUNNING
  3358.         configbbs()
  3359.     endif
  3360. endproc
  3361.  
  3362.  
  3363. #comment
  3364. *********************************************************************
  3365. * 
  3366. * DEFAULTSBBS()
  3367. * 
  3368. * Calls checkchanged(), configbbs()
  3369. * 
  3370. * Called by:
  3371. *     MRUN210H:  parsemenu()
  3372. *     MRUN210C:  changeprompts(), changemaildoor()
  3373. * 
  3374. * Corresponds to the Configure.Defaults.BBS menu selection.
  3375. * 
  3376. *********************************************************************
  3377. #endcomment
  3378.  
  3379. proc defaultsbbs
  3380.     if checkchanged()
  3381.         FLAGS &= RUNNING
  3382.         FLAGS |= DEFAULTS
  3383.         configbbs()
  3384.     endif
  3385. endproc
  3386.  
  3387.  
  3388. #comment
  3389. *********************************************************************
  3390. * 
  3391. * CONFIGBBS()
  3392. * 
  3393. * Calls makefullname(), callscript(), changeuserinfo()
  3394. * 
  3395. * Called by:
  3396. *     MRUN210H:  cfgbbs(), defaultsbbs()
  3397. * 
  3398. * Calls the changebbs script module for the changeuserinfo()
  3399. * procedure.
  3400. * 
  3401. *********************************************************************
  3402. #endcomment
  3403.  
  3404. proc configbbs
  3405. #ifndef MRUN210C
  3406. string changebbs
  3407.         FLAGS = (FLAGS & CLEARCMD) | USR
  3408.         changebbs = makefullname(MailRunDir, "MRUN210C")
  3409.         callscript(changebbs)
  3410. #else
  3411.         changeuserinfo()
  3412. #endif
  3413. endproc
  3414.  
  3415.  
  3416. #comment
  3417. *********************************************************************
  3418. * 
  3419. * CFGPROMPTS()
  3420. * 
  3421. * Calls checkchanged(), checknew(), configprompts
  3422. * 
  3423. * Called by:
  3424. *     MRUN210H:  parsemenu()
  3425. *     MRUN210C:  changeuserinfo(), changemaildoor()
  3426. * 
  3427. * Corresponds to the Configure.BBS_Prompts menu settings.
  3428. * 
  3429. *********************************************************************
  3430. #endcomment
  3431.  
  3432. proc cfgprompts
  3433.     if checkchanged() && checknew()
  3434.         FLAGS &= RUNNING
  3435.         configprompts()
  3436.     endif
  3437. endproc
  3438.  
  3439.  
  3440. #comment
  3441. *********************************************************************
  3442. * 
  3443. * DEFAULTSPROMPTS()
  3444. * 
  3445. * Calls checkchanged(), configprompts()
  3446. * 
  3447. * Called by:
  3448. *     MRUN210H:  parsemenu()
  3449. *     MRUN210C:  changeuserinfo(), changemaildoor()
  3450. * 
  3451. * Corresponds to the Configure.Defaults.Prompts menu selection.
  3452. * 
  3453. *********************************************************************
  3454. #endcomment
  3455.  
  3456. proc defaultsprompts
  3457.     if checkchanged()
  3458.         FLAGS &= RUNNING
  3459.         FLAGS |= DEFAULTS
  3460.         configprompts()
  3461.     endif
  3462. endproc
  3463.  
  3464.  
  3465. #comment
  3466. *********************************************************************
  3467. * 
  3468. * CONFIGPROMPTS()
  3469. * 
  3470. * Calls makefullname(), callscript(), changeprompts()
  3471. * 
  3472. * Called by:
  3473. *     MRUN210H:  cfgprompts(), defaultsprompts()
  3474. * 
  3475. * Calls the changebbs script module for the changeprompts()
  3476. * procedure.
  3477. * 
  3478. *********************************************************************
  3479. #endcomment
  3480.  
  3481. proc configprompts
  3482. #ifndef MRUN210C
  3483. string changebbs
  3484.     FLAGS = (FLAGS & CLEARCMD) | PRMPT
  3485.     changebbs = makefullname(MailRunDir, "MRUN210C")
  3486.     callscript(changebbs)
  3487. #else
  3488.     changeprompts()
  3489. #endif
  3490. endproc
  3491.  
  3492.  
  3493. #comment
  3494. *********************************************************************
  3495. * 
  3496. * CFGMAILDOOR()
  3497. * 
  3498. * Calls checkchanged(), checknew(), configmaildoor()
  3499. * 
  3500. * Called by:
  3501. *     MRUN210H:  parsemenu()
  3502. *     MRUN210C:  changeuserinfo(), changeprompts()
  3503. * 
  3504. * Corresponds to the Configure.BBS_Mail_Door menu selection.
  3505. * 
  3506. *********************************************************************
  3507. #endcomment
  3508.  
  3509. proc cfgmaildoor
  3510.     if checkchanged() && checknew()
  3511.         FLAGS &= RUNNING
  3512.         configmaildoor()
  3513.     endif
  3514. endproc
  3515.  
  3516.  
  3517. #comment
  3518. *********************************************************************
  3519. * 
  3520. * DEFAULTSDOOR()
  3521. * 
  3522. * Calls checkchanged(), configmaildoor()
  3523. * 
  3524. * Called by:
  3525. *     MRUN210H:  parsemenu()
  3526. *     MRUN210C:  changeuserinfo(), changeprompts()
  3527. * 
  3528. * Corresponds to the Configure.Defaults.Mail_Door menu selection.
  3529. * 
  3530. *********************************************************************
  3531. #endcomment
  3532.  
  3533. proc defaultsdoor
  3534.     if checkchanged()
  3535.         FLAGS &= RUNNING
  3536.         FLAGS |= DEFAULTS
  3537.         configmaildoor()
  3538.     endif
  3539. endproc
  3540.  
  3541.  
  3542. #comment
  3543. *********************************************************************
  3544. * 
  3545. * CONFIGMAILDOOR()
  3546. * 
  3547. * Calls makefullname(), callscript(), changemaildoor()
  3548. * 
  3549. * Called by:
  3550. *     MRUN210H:  cfgmaildoor(), defaultsmaildoor()
  3551. * 
  3552. * Calls the changebbs script module for the changemaildoor()
  3553. * procedure.
  3554. * 
  3555. *********************************************************************
  3556. #endcomment
  3557.  
  3558. proc configmaildoor
  3559. #ifndef MRUN210C
  3560. string changebbs
  3561.     FLAGS = (FLAGS & CLEARCMD) | QMD
  3562.     changebbs = makefullname(MailRunDir, "MRUN210C")
  3563.     callscript(changebbs)
  3564. #else
  3565.     changemaildoor()
  3566. #endif
  3567. endproc
  3568.  
  3569.  
  3570. #comment
  3571. *********************************************************************
  3572. * 
  3573. * ADDNEWBBS()
  3574. * 
  3575. * Calls checkchanged(), makefullname(), callscript()
  3576. * MRUN210C\changeuserinfo()
  3577. * 
  3578. * Called by:
  3579. *     MRUN210H:  parsemenu(), parseobject()
  3580. * 
  3581. * Corresponds to the Add.New_BBS menu selection.  Calls the
  3582. * changebbs module for the changeuserinfo() procedure with 
  3583. * the NEW flag set.
  3584. * 
  3585. *********************************************************************
  3586. #endcomment
  3587.  
  3588. proc addnewbbs
  3589. #ifndef MRUN210C
  3590. string changebbs
  3591. #endif
  3592.     if checkchanged()
  3593.         FLAGS &= RUNNING
  3594.         FLAGS |= NEW
  3595. #ifndef MRUN210C
  3596.         FLAGS = (FLAGS & CLEARCMD) | USR
  3597.         changebbs = makefullname(MailRunDir, "MRUN210C")
  3598.         callscript(changebbs)
  3599. #else
  3600.         changeuserinfo()
  3601. #endif
  3602.     endif
  3603. endproc
  3604.  
  3605.  
  3606. #comment
  3607. *********************************************************************
  3608. * 
  3609. * ADDGETSEND()
  3610. * 
  3611. * Calls checkchanged(), checknew(), makefullname(), callscript()
  3612. * MRUN210F\addgetmail()
  3613. * 
  3614. * Called by:
  3615. *     MRUN210H:  parsemenu(), parseobject()
  3616. * 
  3617. * Corresponds to the Add.Get/Send_Mail menu selection.  Calls
  3618. * the othercmds script module for the addgetmail() procedure.
  3619. * 
  3620. *********************************************************************
  3621. #endcomment
  3622.  
  3623. proc addgetsend
  3624. #ifndef MRUN210F
  3625. string othercmds
  3626. #endif
  3627.     if checkchanged() && checknew()
  3628.         FLAGS &= RUNNING
  3629. #ifndef MRUN210F
  3630.         FLAGS = (FLAGS & CLEARCMD) | AGM
  3631.         othercmds = makefullname(MailRunDir, "MRUN210F")
  3632.         callscript(othercmds)
  3633. #else
  3634.         addgetmail()
  3635. #endif
  3636.     endif
  3637. endproc
  3638.  
  3639.  
  3640. #comment
  3641. *********************************************************************
  3642. * 
  3643. * ADDDOWNLOAD()
  3644. * 
  3645. * Calls checkchanged(), checknew(), makefullname(), callscript()
  3646. * 
  3647. * Called by:
  3648. *     MRUN210H:  parsemenu(), parseobject()
  3649. * 
  3650. * Corresponds to the Add.Download_File menu selection.  Calls
  3651. * the adddlfile script module.
  3652. * 
  3653. *********************************************************************
  3654. #endcomment
  3655.  
  3656. proc adddownload
  3657. #ifndef MRUN210D
  3658. string adddlfile
  3659.     if checkchanged() && checknew()
  3660.         FLAGS &= RUNNING
  3661.         adddlfile = makefullname(MailRunDir, "MRUN210D")
  3662.         callscript(adddlfile)
  3663.     endif
  3664. #endif
  3665. endproc
  3666.  
  3667.  
  3668. #comment
  3669. *********************************************************************
  3670. * 
  3671. * ADDUPLOAD()
  3672. * 
  3673. * Calls checkchanged(), checknew(), makefullname(), callscript()
  3674. * 
  3675. * Called by:
  3676. *     MRUN210H:  parsemenu(), parseobject()
  3677. *     
  3678. * Corresponds to the Add.Upload_File menu selection.  Calls
  3679. * the addulfile script module.
  3680. * 
  3681. *********************************************************************
  3682. #endcomment
  3683.  
  3684. proc addupload
  3685. #ifndef MRUN210E
  3686. string addulfile
  3687.     if checkchanged() && checknew()
  3688.         FLAGS &= RUNNING
  3689.         addulfile = makefullname(MailRunDir, "MRUN210E")
  3690.         callscript(addulfile)
  3691.     endif
  3692. #endif
  3693. endproc
  3694.  
  3695.  
  3696. #comment
  3697. *********************************************************************
  3698. * 
  3699. * ADDSENDCMD()
  3700. * 
  3701. * Calls checkchanged(), checknew(), makefullname(), callscript(),
  3702. * MRUN210F\addsendcommand()
  3703. * 
  3704. * Called by:
  3705. *     MRUN210H:  parsemenu(), parseobject()
  3706. *     
  3707. * Corresponds to the Add.Send_Command menu selection.  Calls
  3708. * the othercmds script module for the addsendcommand() procedure.
  3709. * 
  3710. *********************************************************************
  3711. #endcomment
  3712.  
  3713. proc addsendcmd
  3714. #ifndef MRUN210F
  3715. string othercmds
  3716. #endif
  3717.     if checkchanged() && checknew()
  3718.         FLAGS &= RUNNING
  3719. #ifndef MRUN210F
  3720.         FLAGS = (FLAGS & CLEARCMD) | CMD
  3721.         othercmds = makefullname(MailRunDir, "MRUN210F")
  3722.         callscript(othercmds)
  3723. #else
  3724.         addsendcommand()
  3725. #endif
  3726.     endif
  3727. endproc
  3728.  
  3729.  
  3730. #comment
  3731. *********************************************************************
  3732. * 
  3733. * ADDSCRIPT()
  3734. * 
  3735. * Calls checkchanged(), checknew(), makefullname(), callscript(),
  3736. * MRUN210F\adddoscript()
  3737. * 
  3738. * Called by:
  3739. *     MRUN210H:  parsemenu(), parseobject()
  3740. *     
  3741. * Corresponds to the Add.Execute_Script menu selection.  Calls
  3742. * the othercmds script module for the adddoscript() procedure.
  3743. * 
  3744. *********************************************************************
  3745. #endcomment
  3746.  
  3747. proc addscript
  3748. #ifndef MRUN210F
  3749. string othercmds
  3750. #endif
  3751.     if checkchanged() && checknew()
  3752.         FLAGS &= RUNNING
  3753. #ifndef MRUN210F
  3754.         FLAGS = (FLAGS & CLEARCMD) | SCR
  3755.         othercmds = makefullname(MailRunDir, "MRUN210F")
  3756.         callscript(othercmds)
  3757. #else
  3758.         adddoscript()
  3759. #endif
  3760.     endif
  3761. endproc
  3762.  
  3763.  
  3764. #comment
  3765. *********************************************************************
  3766. * 
  3767. * EXECUTEMAILRUN()
  3768. * 
  3769. * Called by:
  3770. *     MRUN210H:  parsemenu(), parseobject()
  3771. *     
  3772. * Corresponds to the Execute.Execute/Terminate_MailRun menu
  3773. * selection.
  3774. * 
  3775. *********************************************************************
  3776. #endcomment
  3777.  
  3778. proc executemailrun
  3779. #ifdef MRUN210G
  3780.     hangup
  3781.     FLAGS &= IDLE
  3782.     capture OFF
  3783.     exit
  3784. #else
  3785.     if FLAGS & RUNNING
  3786.         FLAGS &= IDLE
  3787.     else
  3788.         FLAGS |= RUNNING
  3789.     endif
  3790. #endif
  3791. endproc
  3792.  
  3793.  
  3794. #comment
  3795. *********************************************************************
  3796. * 
  3797. * EXECUTEARCHIVER()
  3798. * 
  3799. * Calls checktask()
  3800. * 
  3801. * Called by:
  3802. *     MRUN210H:  parsemenu(), parseobject()
  3803. * 
  3804. * Corresponds to the Execute.Archiver menu selection.  Calls
  3805. * the archive utility specified in the MailRun Settings
  3806. * dialog.
  3807. * 
  3808. *********************************************************************
  3809. #endcomment
  3810.  
  3811. proc executearchiver
  3812. integer i
  3813. #ifndef MRUN210AB
  3814. string Archiver
  3815. #endif
  3816.     profilerd MailRun "MailRun" "Archiver" Archiver
  3817.     if not NULLSTR Archiver
  3818.         i = checktask(Archiver)
  3819.         if i
  3820.             activatetask i
  3821.         else
  3822.             run Archiver
  3823.         endif
  3824.         if FAILURE
  3825.             usermsg "Unable to run Archive Utility %s .`r`n\
  3826. The file does not exist or is not in your DOS path." Archiver
  3827.         endif
  3828.     else
  3829.         usermsg "You must specify an Archive Utility in`r`n\
  3830. the MailRun Settings dialog box."
  3831.     endif
  3832. endproc
  3833.  
  3834.  
  3835. #comment
  3836. *********************************************************************
  3837. * 
  3838. * EXECUTEQWKREADER()
  3839. * 
  3840. * Calls checktask()
  3841. * 
  3842. * Called by:
  3843. *     MRUN210H:  parsemenu(), parseobject()
  3844. * 
  3845. * Corresponds to the Execute.QWK_Reader menu selection.  Calls
  3846. * the QWK mail reader specified in the MailRun Settings
  3847. * dialog.
  3848. * 
  3849. *********************************************************************
  3850. #endcomment
  3851.  
  3852. proc executeqwkreader
  3853. integer i
  3854. #ifndef MRUN210AB
  3855. string QWKReader
  3856. #endif
  3857.     profilerd MailRun "MailRun" "QWKReader" QWKReader
  3858.     if not NULLSTR QWKReader
  3859.         i = checktask(QWKReader)
  3860.         if i
  3861.             activatetask i
  3862.         else
  3863.             run QWKReader
  3864.         endif
  3865.         if FAILURE
  3866.             usermsg "Unable to run QWK Mail Reader %s.`r`n\
  3867. The file does not exist or is not in your DOS path." QWKReader
  3868.         endif
  3869.     else
  3870.         usermsg "You must specify a QWK Mail Reader in`r`n\
  3871. the MailRun Settings dialog box."
  3872.     endif
  3873. endproc
  3874.  
  3875.  
  3876. #comment
  3877. *********************************************************************
  3878. * 
  3879. * EXECUTELOGVIEWER()
  3880. * 
  3881. * Calls checktask(), makefullname()
  3882. * 
  3883. * Called by:
  3884. *     MRUN210H:  parsemenu(), parseobject()
  3885. *     
  3886. * Corresponds to the Execute.View_Log_File menu selection.  
  3887. * Calls the file viewer specified in the MailRun Settings
  3888. * dialog and loads the log file for the current mailrun.
  3889. * 
  3890. *********************************************************************
  3891. #endcomment
  3892.  
  3893. proc executelogviewer
  3894. string CapFile, RunLine, WinTitle
  3895. integer i, j
  3896. #ifndef MRUN210AB
  3897. string LogViewer
  3898. #endif
  3899.     profilerd MailRun "MailRun" "LogViewer" LogViewer
  3900.     if not NULLSTR LogViewer
  3901.         if not NULLSTR MailRunTrunc
  3902.             CapFile = makefullname(MailRunDir, MailRunTrunc)
  3903.             strlwr CapFile
  3904.             strreplace CapFile ".mrn" ".cap"
  3905.         else
  3906.             CapFile = ""
  3907.         endif
  3908.         i = checktask(LogViewer)
  3909.         if i
  3910.             taskwin i j
  3911.             getwintext j WinTitle
  3912.             if strfind WinTitle CapFile
  3913.                 activatetask i
  3914.                 return
  3915.             endif
  3916.         endif
  3917.         strfmt RunLine "%s %s" LogViewer CapFile
  3918.         run RunLine
  3919.         if FAILURE
  3920.             usermsg "Unable to run Log File Viewer %s.`r`n\
  3921. The file does not exist or is not in your DOS path." LogViewer
  3922.         endif
  3923.     else
  3924.         usermsg "You must specify a Log File Viewer in`r`n\
  3925. the MailRun Settings dialog box."
  3926.     endif
  3927. endproc
  3928.  
  3929.  
  3930. #comment
  3931. *********************************************************************
  3932. * 
  3933. * HELPCONTENTS()
  3934. * 
  3935. * Called by:
  3936. *     MRUN210H:  parsemenu()
  3937. * 
  3938. * Corresponds to the Help.Contents menu selection.  Calls 
  3939. * the help file and displays the contents page.
  3940. * 
  3941. *********************************************************************
  3942. #endcomment
  3943.  
  3944. proc helpcontents
  3945.     help 1
  3946. endproc
  3947.  
  3948.  
  3949. #comment
  3950. *********************************************************************
  3951. * 
  3952. * HELPCONTEXT()
  3953. * 
  3954. * Called by:
  3955. *     MRUN210H:  parsemenu(), parseobject()
  3956. * 
  3957. * Corresponds to the Help.On_current_window menu selection.
  3958. * Calls the help file and displays the page appropriate for
  3959. * the current dialog box.  HelpPage is a global variable set
  3960. * in each procedure that calls a dialog box.
  3961. * 
  3962. *********************************************************************
  3963. #endcomment
  3964.  
  3965. proc helpcontext
  3966.     help HelpPage
  3967. endproc
  3968.  
  3969.  
  3970. #comment
  3971. *********************************************************************
  3972. * 
  3973. * HELPABOUT()
  3974. * 
  3975. * Calls checkchanged(), makefullname(), callscript(),
  3976. * MRUN210F\showabout()
  3977. * 
  3978. * Called by:
  3979. *     MRUN210H:  parsemenu()
  3980. *     MRUN210A:  main()
  3981. * 
  3982. * Corresponds to the Help.About_MailRun menu selection.  Calls
  3983. * the othercmds script module for the showabout() procedure.
  3984. * 
  3985. *********************************************************************
  3986. #endcomment
  3987.  
  3988. proc helpabout
  3989. #ifndef MRUN210F
  3990. string othercmds
  3991. #endif
  3992.     if checkchanged()
  3993.         FLAGS &= RUNNING
  3994. #ifndef MRUN210F
  3995.         FLAGS = (FLAGS & CLEARCMD) | ABT
  3996.         othercmds = makefullname(MailRunDir, "MRUN210F")
  3997.         callscript(othercmds)
  3998. #else
  3999.         showabout()
  4000. #endif
  4001.     endif
  4002. endproc
  4003.  
  4004.  
  4005. #comment
  4006. *********************************************************************
  4007. * 
  4008. * CALLSCRIPT()
  4009. * 
  4010. * Calls menudim(), makemailrunlist(), makebbslist(),
  4011. * maketasklist(), getfirstitem(), MRUN210AG\mailrunbox()
  4012. * 
  4013. * Called by:
  4014. *     MRUN210H:  filenewmrun(), configmrun(), configbbs(),
  4015. *                   configprompts(), configmaildoor(), addnewbbs(),
  4016. *                   addgetsend(), adddownload(), addupload(),
  4017. *                   addsendcmd(), addscript(), helpabout()
  4018. * 
  4019. * Executes the specified MailRun script module.
  4020. * 
  4021. *********************************************************************
  4022. #endcomment
  4023.  
  4024. proc callscript
  4025. strparm ScriptTitle
  4026. #ifndef MRUN210AG
  4027.     chain ScriptTitle
  4028. #else
  4029. string LastMRun
  4030.     LastMRun = MailRun
  4031.     execute ScriptTitle
  4032.     menudim()
  4033.     FLAGS &= RUNNING
  4034. #ifdef MRUN210G
  4035.     if !(FLAGS & RUNNING)
  4036.         ;if the mailrun has been terminated from another script module...
  4037.         executemailrun()
  4038.     endif
  4039.     profilerd MailRun "MailRun" "LogRun" LogRun
  4040.     if LogRun
  4041.         profilerd MailRun "MailRun" "AnsiInLog" AnsiInLog
  4042.         if AnsiInLog
  4043.             set capture mode append RAW
  4044.         else
  4045.             set capture mode append VISUAL
  4046.         endif
  4047.         capture ON
  4048.     else
  4049.         capture OFF
  4050.     endif
  4051. #else
  4052.     findfirst MailRun
  4053.     MailRunTrunc = $FILENAME
  4054.     makemailrunlist()
  4055.     makebbslist()
  4056. #endif
  4057.     maketasklist()
  4058.     if not strcmpi LastMRun MailRun
  4059.         getfirstitem()
  4060.     endif
  4061.     mailrunbox()
  4062.     statmsg ""
  4063. #endif
  4064. endproc
  4065.  
  4066.  
  4067.  
  4068.